net-libs/gssdp/gssdp-1.2.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5 VALA_USE_DEPEND="vapigen"
   6
   7 inherit gnome.org meson multilib-minimal vala xdg
   8
   9 DESCRIPTION="GObject-based API for handling resource discovery and announcement over SSDP"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
  11
  12 LICENSE="LGPL-2+"
  13 SLOT="0/1.2-0" # <API version>-<soname>
  14 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ppc64 ~sparc x86"
  15 IUSE="gtk-doc +introspection gtk vala"
  16 REQUIRED_USE="vala? ( introspection )"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.54:2[${MULTILIB_USEDEP}]
  20         >=net-libs/libsoup-2.26.1:2.4[${MULTILIB_USEDEP},introspection?]
  21         gtk? ( >=x11-libs/gtk+-3.12:3 )
  22         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  23 "
  24 DEPEND="${RDEPEND}"
  25 BDEPEND="
  26         gtk-doc? ( >=dev-util/gtk-doc-1.14
  27                 app-text/docbook-xml-dtd:4.1.2 )
  28         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  29         vala? (
  30                 $(vala_depend)
  31                 net-libs/libsoup:2.4[vala]
  32         )
  33 "
  34
  35 src_prepare() {
  36         use vala && vala_src_prepare
  37         xdg_src_prepare
  38 }
  39
  40 multilib_src_configure() {
  41         local emesonargs=(
  42                 -Dgtk_doc=$(multilib_native_usex gtk-doc true false)
  43                 -Dsniffer=$(multilib_native_usex gtk true false)
  44                 -Dintrospection=$(multilib_native_usex introspection true false)
  45                 -Dvapi=$(multilib_native_usex vala true false)
  46                 -Dexamples=false
  47         )
  48         meson_src_configure
  49 }
  50
  51 multilib_src_compile() {
  52         meson_src_compile
  53 }
  54
  55 multilib_src_test() {
  56         meson_src_test
  57 }
  58
  59 multilib_src_install() {
  60         meson_src_install
  61 }