net-libs/gssdp/gssdp-0.14.11.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7 VALA_MIN_API_VERSION="0.14"
   8 VALA_USE_DEPEND="vapigen"
   9
  10 inherit gnome2 multilib-minimal vala
  11
  12 DESCRIPTION="A GObject-based API for handling resource discovery and announcement over SSDP"
  13 HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="0/3"
  17 KEYWORDS="~alpha amd64 ~arm hppa ~ia64 ~ppc ppc64 ~sparc x86 ~x86-fbsd"
  18 IUSE="+introspection +gtk"
  19
  20 RDEPEND="
  21         >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  22         >=net-libs/libsoup-2.44.2:2.4[${MULTILIB_USEDEP},introspection?]
  23         gtk? ( >=x11-libs/gtk+-3.0:3 )
  24         introspection? (
  25                 $(vala_depend)
  26                 >=dev-libs/gobject-introspection-0.6.7 )
  27         !<net-libs/gupnp-vala-0.10.3
  28 "
  29 DEPEND="${RDEPEND}
  30         >=dev-util/gtk-doc-am-1.10
  31         sys-devel/gettext
  32         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  33 "
  34
  35 src_prepare() {
  36         # Disable functional test as it requires port that might be used by rygel to
  37         # be free of use
  38         sed 's/\(check_PROGRAMS.*\)test-functional$(EXEEXT)/\1/' \
  39                 -i "${S}"/tests/gtest/Makefile.in || die
  40
  41         use introspection && vala_src_prepare
  42         gnome2_src_prepare
  43 }
  44
  45 multilib_src_configure() {
  46         ECONF_SOURCE=${S} \
  47         gnome2_src_configure \
  48                 $(multilib_native_use_enable introspection) \
  49                 $(multilib_native_use_with gtk) \
  50                 --disable-static
  51
  52         if multilib_is_native_abi; then
  53                 # fix gtk-doc
  54                 ln -s "${S}"/doc/html doc/html || die
  55         fi
  56 }
  57
  58 multilib_src_install() {
  59         gnome2_src_install
  60 }