net-libs/google-cloud-cpp/google-cloud-cpp-0.5.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils
   7
   8 JSON_VER="3.4.0"
   9 GOOGLEAPIS_COMMIT="6a3277c0656219174ff7c345f31fb20a90b30b97"
  10
  11 DESCRIPTION="Google Cloud Client Library for C++"
  12 HOMEPAGE="https://cloud.google.com/"
  13 SRC_URI="https://github.com/GoogleCloudPlatform/google-cloud-cpp/archive/v${PV}.tar.gz -> ${P}.tar.gz
  14         https://github.com/nlohmann/json/releases/download/v${JSON_VER}/json.hpp -> nlohmann-json-${JSON_VER}-json.hpp
  15         https://github.com/googleapis/googleapis/archive/${GOOGLEAPIS_COMMIT}.tar.gz -> googleapis-${GOOGLEAPIS_COMMIT}.tar.gz"
  16
  17 LICENSE="Apache-2.0"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE=""
  21
  22 RESTRICT="test"
  23 RDEPEND="dev-libs/protobuf
  24         net-misc/curl
  25         net-libs/grpc"
  26 DEPEND="${RDEPEND}"
  27
  28 DOCS=( README.md )
  29 PATCHES=(
  30         "${FILESDIR}/google-cloud-cpp-0.5.0-openssl.patch"
  31 )
  32
  33 src_prepare() {
  34         rm -rf "${S}/third_party/googleapis/" || die
  35         mv "${WORKDIR}/googleapis-${GOOGLEAPIS_COMMIT}/" "${S}/third_party/googleapis/" || die
  36
  37         cmake-utils_src_prepare
  38 }
  39
  40 src_configure() {
  41         local mycmakeargs=(
  42                 -DGOOGLE_CLOUD_CPP_CRC32C_PROVIDER=package
  43                 -DGOOGLE_CLOUD_CPP_CURL_PROVIDER=package
  44                 -DGOOGLE_CLOUD_CPP_GMOCK_PROVIDER=package
  45                 -DGOOGLE_CLOUD_CPP_GRPC_PROVIDER=pkg-config
  46                 -DBUILD_SHARED_LIBS=ON
  47                 -DBUILD_TESTING=OFF
  48         )
  49
  50         cmake-utils_src_configure
  51
  52         mkdir -p "${BUILD_DIR}/external/nlohmann_json/src/" || die
  53         cp "${DISTDIR}/nlohmann-json-${JSON_VER}-json.hpp" "${BUILD_DIR}/external/nlohmann_json/src/json.hpp" || die
  54 }
  55
  56 src_test() {
  57         # test fails
  58         local myctestargs=(
  59                 -E internal_parse_rfc3339_test
  60         )
  61
  62         cmake-utils_src_test
  63 }