net-libs/gnutls/gnutls-3.6.7.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit libtool multilib-minimal
   7
   8 DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
   9 HOMEPAGE="http://www.gnutls.org/"
  10 SRC_URI="mirror://gnupg/gnutls/v$(ver_cut 1-2)/${P}.tar.xz"
  11
  12 LICENSE="GPL-3 LGPL-2.1"
  13 SLOT="0/30" # libgnutls.so number
  14 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="+cxx dane doc examples guile +idn nls +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools valgrind"
  16
  17 REQUIRED_USE="
  18         test-full? ( cxx dane doc examples guile idn nls openssl pkcs11 seccomp tls-heartbeat tools )"
  19
  20 # NOTICE: sys-devel/autogen is required at runtime as we
  21 # use system libopts
  22 RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
  23         dev-libs/libunistring:=[${MULTILIB_USEDEP}]
  24         >=dev-libs/nettle-3.4.1:=[gmp,${MULTILIB_USEDEP}]
  25         >=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
  26         tools? ( sys-devel/autogen:= )
  27         dane? ( >=net-dns/unbound-1.4.20:=[${MULTILIB_USEDEP}] )
  28         guile? ( >=dev-scheme/guile-2:=[networking] )
  29         nls? ( >=virtual/libintl-0-r1:=[${MULTILIB_USEDEP}] )
  30         pkcs11? ( >=app-crypt/p11-kit-0.23.1:=[${MULTILIB_USEDEP}] )
  31         idn? ( >=net-dns/libidn2-0.16-r1:=[${MULTILIB_USEDEP}] )"
  32 DEPEND="${RDEPEND}
  33         test? (
  34                 seccomp? ( sys-libs/libseccomp )
  35         )"
  36 BDEPEND=">=virtual/pkgconfig-0-r1
  37         doc? ( dev-util/gtk-doc )
  38         nls? ( sys-devel/gettext )
  39         tools? ( sys-devel/autogen )
  40         valgrind? ( dev-util/valgrind )
  41         test-full? (
  42                 app-crypt/dieharder
  43                 >=app-misc/datefudge-1.22
  44                 dev-libs/softhsm:2[-bindist]
  45                 net-dialup/ppp
  46                 net-misc/socat
  47         )"
  48
  49 DOCS=(
  50         README.md
  51         doc/certtool.cfg
  52 )
  53
  54 HTML_DOCS=()
  55
  56 pkg_setup() {
  57         # bug#520818
  58         export TZ=UTC
  59
  60         use doc && HTML_DOCS+=(
  61                 doc/gnutls.html
  62         )
  63 }
  64
  65 src_prepare() {
  66         default
  67
  68         # force regeneration of autogen-ed files
  69         local file
  70         for file in $(grep -l AutoGen-ed src/*.c) ; do
  71                 rm src/$(basename ${file} .c).{c,h} || die
  72         done
  73
  74         # Use sane .so versioning on FreeBSD.
  75         elibtoolize
  76 }
  77
  78 multilib_src_configure() {
  79         LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
  80
  81         # TPM needs to be tested before being enabled
  82         libconf+=( --without-tpm )
  83
  84         # hardware-accell is disabled on OSX because the asm files force
  85         #   GNU-stack (as doesn't support that) and when that's removed ld
  86         #   complains about duplicate symbols
  87         [[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
  88
  89         # Cygwin as does not understand these asm files at all
  90         [[ ${CHOST} == *-cygwin* ]] && libconf+=( --disable-hardware-acceleration )
  91
  92         ECONF_SOURCE=${S} econf \
  93                 $(multilib_native_enable manpages) \
  94                 $(multilib_native_use_enable doc gtk-doc) \
  95                 $(multilib_native_use_enable doc) \
  96                 $(multilib_native_use_enable guile) \
  97                 $(multilib_native_use_enable seccomp seccomp-tests) \
  98                 $(multilib_native_use_enable test tests) \
  99                 $(multilib_native_use_enable test-full full-test-suite) \
 100                 $(multilib_native_use_enable tools) \
 101                 $(multilib_native_use_enable valgrind valgrind-tests) \
 102                 $(use_enable cxx) \
 103                 $(use_enable dane libdane) \
 104                 $(use_enable nls) \
 105                 $(use_enable openssl openssl-compatibility) \
 106                 $(use_enable sslv2 ssl2-support) \
 107                 $(use_enable sslv3 ssl3-support) \
 108                 $(use_enable static-libs static) \
 109                 $(use_enable tls-heartbeat heartbeat-support) \
 110                 $(use_with idn) \
 111                 $(use_with pkcs11 p11-kit) \
 112                 --disable-rpath \
 113                 --with-unbound-root-key-file="${EPREFIX}/etc/dnssec/root-anchors.txt" \
 114                 --without-included-libtasn1 \
 115                 "${libconf[@]}" \
 116                 $("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g')
 117 }
 118
 119 multilib_src_install_all() {
 120         einstalldocs
 121         find "${D}" -name '*.la' -delete || die
 122
 123         if use examples; then
 124                 docinto examples
 125                 dodoc doc/examples/*.c
 126         fi
 127 }