net-libs/gnutls/gnutls-3.6.5.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit libtool multilib-minimal
   7
   8 DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
   9 HOMEPAGE="http://www.gnutls.org/"
  10 SRC_URI="mirror://gnupg/gnutls/v$(ver_cut 1-2)/${P}.tar.xz"
  11
  12 LICENSE="GPL-3 LGPL-2.1"
  13 SLOT="0/30" # libgnutls.so number
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="+cxx dane doc examples guile +idn nls +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools valgrind"
  16
  17 REQUIRED_USE="
  18         test-full? ( cxx dane doc examples guile idn nls openssl pkcs11 seccomp tls-heartbeat tools )"
  19
  20 # NOTICE: sys-devel/autogen is required at runtime as we
  21 # use system libopts
  22 RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
  23         dev-libs/libunistring:=[${MULTILIB_USEDEP}]
  24         >=dev-libs/nettle-3.4.1:=[gmp,${MULTILIB_USEDEP}]
  25         >=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
  26         tools? ( sys-devel/autogen:= )
  27         dane? ( >=net-dns/unbound-1.4.20:=[${MULTILIB_USEDEP}] )
  28         guile? ( >=dev-scheme/guile-2:=[networking] )
  29         nls? ( >=virtual/libintl-0-r1:=[${MULTILIB_USEDEP}] )
  30         pkcs11? ( >=app-crypt/p11-kit-0.23.1:=[${MULTILIB_USEDEP}] )
  31         idn? ( >=net-dns/libidn2-0.16-r1:=[${MULTILIB_USEDEP}] )"
  32 DEPEND="${RDEPEND}
  33         test? (
  34                 seccomp? ( sys-libs/libseccomp )
  35         )"
  36 BDEPEND=">=virtual/pkgconfig-0-r1
  37         doc? ( dev-util/gtk-doc )
  38         nls? ( sys-devel/gettext )
  39         tools? ( sys-devel/autogen )
  40         valgrind? ( dev-util/valgrind )
  41         test-full? (
  42                 app-crypt/dieharder
  43                 >=app-misc/datefudge-1.22
  44                 dev-libs/softhsm:2[-bindist]
  45                 net-dialup/ppp
  46                 net-misc/socat
  47         )"
  48
  49 DOCS=(
  50         README.md
  51         doc/certtool.cfg
  52 )
  53
  54 HTML_DOCS=()
  55
  56 PATCHES=(
  57         "${FILESDIR}/${P}-build.patch"
  58         "${FILESDIR}/${P}-libressl.patch"
  59 )
  60
  61 pkg_setup() {
  62         # bug#520818
  63         export TZ=UTC
  64
  65         use doc && HTML_DOCS+=(
  66                 doc/gnutls.html
  67         )
  68 }
  69
  70 src_prepare() {
  71         default
  72
  73         # force regeneration of autogen-ed files
  74         local file
  75         for file in $(grep -l AutoGen-ed src/*.c) ; do
  76                 rm src/$(basename ${file} .c).{c,h} || die
  77         done
  78
  79         # Use sane .so versioning on FreeBSD.
  80         elibtoolize
  81
  82         # detect also guile-2.2, bug#673574
  83         # aclocal/autoreconf will require more dependencies
  84         # that we want to have
  85         sed -i 's/\(_guile_versions_to_search="\)\(.*\)\("\)/\1\2 2.2\3/' configure || die
  86 }
  87
  88 multilib_src_configure() {
  89         LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
  90
  91         # TPM needs to be tested before being enabled
  92         libconf+=( --without-tpm )
  93
  94         # hardware-accell is disabled on OSX because the asm files force
  95         #   GNU-stack (as doesn't support that) and when that's removed ld
  96         #   complains about duplicate symbols
  97         [[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
  98
  99         # Cygwin as does not understand these asm files at all
 100         [[ ${CHOST} == *-cygwin* ]] && libconf+=( --disable-hardware-acceleration )
 101
 102         ECONF_SOURCE=${S} econf \
 103                 $(multilib_native_enable manpages) \
 104                 $(multilib_native_use_enable doc gtk-doc) \
 105                 $(multilib_native_use_enable doc) \
 106                 $(multilib_native_use_enable guile) \
 107                 $(multilib_native_use_enable seccomp seccomp-tests) \
 108                 $(multilib_native_use_enable test tests) \
 109                 $(multilib_native_use_enable test-full full-test-suite) \
 110                 $(multilib_native_use_enable tools) \
 111                 $(multilib_native_use_enable valgrind valgrind-tests) \
 112                 $(use_enable cxx) \
 113                 $(use_enable dane libdane) \
 114                 $(use_enable nls) \
 115                 $(use_enable openssl openssl-compatibility) \
 116                 $(use_enable sslv2 ssl2-support) \
 117                 $(use_enable sslv3 ssl3-support) \
 118                 $(use_enable static-libs static) \
 119                 $(use_enable tls-heartbeat heartbeat-support) \
 120                 $(use_with idn) \
 121                 $(use_with pkcs11 p11-kit) \
 122                 --disable-rpath \
 123                 --with-unbound-root-key-file="${EPREFIX}/etc/dnssec/root-anchors.txt" \
 124                 --without-included-libtasn1 \
 125                 "${libconf[@]}" \
 126                 $("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g')
 127 }
 128
 129 multilib_src_install_all() {
 130         einstalldocs
 131         find "${D}" -name '*.la' -delete || die
 132
 133         if use examples; then
 134                 docinto examples
 135                 dodoc doc/examples/*.c
 136         fi
 137 }