net-libs/gnutls/gnutls-3.5.15.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit libtool ltprune multilib-minimal versionator
   7
   8 DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
   9 HOMEPAGE="http://www.gnutls.org/"
  10 SRC_URI="mirror://gnupg/gnutls/v$(get_version_component_range 1-2)/${P}.tar.xz"
  11
  12 LICENSE="GPL-3 LGPL-2.1"
  13 SLOT="0/30" # libgnutls.so number
  14 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  15 IUSE="+cxx dane doc examples guile +idn nls openpgp +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools valgrind zlib"
  16
  17 REQUIRED_USE="
  18         test-full? ( guile pkcs11 openpgp openssl idn seccomp tools zlib )"
  19
  20 # NOTICE: sys-devel/autogen is required at runtime as we
  21 # use system libopts
  22 RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
  23         dev-libs/libunistring:=[${MULTILIB_USEDEP}]
  24         >=dev-libs/nettle-3.1:=[gmp,${MULTILIB_USEDEP}]
  25         >=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
  26         tools? ( sys-devel/autogen )
  27         dane? ( >=net-dns/unbound-1.4.20[${MULTILIB_USEDEP}] )
  28         guile? ( >=dev-scheme/guile-1.8:=[networking] )
  29         nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
  30         pkcs11? ( >=app-crypt/p11-kit-0.23.1[${MULTILIB_USEDEP}] )
  31         zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
  32         idn? ( >=net-dns/libidn2-0.16-r1[${MULTILIB_USEDEP}] )"
  33 DEPEND="${RDEPEND}
  34         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
  35         doc? ( dev-util/gtk-doc )
  36         nls? ( sys-devel/gettext )
  37         valgrind? ( dev-util/valgrind )
  38         test? (
  39                 seccomp? ( sys-libs/libseccomp )
  40         )
  41         test-full? (
  42                 guile? ( >=dev-scheme/guile-2 )
  43                 app-crypt/dieharder
  44                 app-misc/datefudge
  45                 dev-libs/softhsm:2[-bindist]
  46                 net-dialup/ppp
  47                 net-misc/socat
  48         )"
  49
  50 DOCS=(
  51         README.md
  52         doc/certtool.cfg
  53 )
  54
  55 HTML_DOCS=()
  56
  57 pkg_setup() {
  58         # bug#520818
  59         export TZ=UTC
  60
  61         use doc && HTML_DOCS+=(
  62                 doc/gnutls.html
  63         )
  64 }
  65
  66 src_prepare() {
  67         default
  68
  69         # force regeneration of autogen-ed files
  70         local file
  71         for file in $(grep -l AutoGen-ed src/*.c) ; do
  72                 rm src/$(basename ${file} .c).{c,h} || die
  73         done
  74
  75         # Use sane .so versioning on FreeBSD.
  76         elibtoolize
  77 }
  78
  79 multilib_src_configure() {
  80         LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
  81
  82         # remove magic of library detection
  83         # bug#438222
  84         local libconf=($("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g'))
  85
  86         # TPM needs to be tested before being enabled
  87         libconf+=( --without-tpm )
  88
  89         # hardware-accell is disabled on OSX because the asm files force
  90         #   GNU-stack (as doesn't support that) and when that's removed ld
  91         #   complains about duplicate symbols
  92         [[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
  93
  94         # Cygwin as does not understand these asm files at all
  95         [[ ${CHOST} == *-cygwin* ]] && libconf+=( --disable-hardware-acceleration )
  96
  97         ECONF_SOURCE=${S} econf \
  98                 $(multilib_native_enable manpages) \
  99                 $(multilib_native_use_enable doc gtk-doc) \
 100                 $(multilib_native_use_enable doc) \
 101                 $(multilib_native_use_enable guile) \
 102                 $(multilib_native_use_enable seccomp seccomp-tests) \
 103                 $(multilib_native_use_enable test tests) \
 104                 $(multilib_native_use_enable test-full full-test-suite) \
 105                 $(multilib_native_use_enable tools) \
 106                 $(multilib_native_use_enable valgrind valgrind-tests) \
 107                 $(use_enable cxx) \
 108                 $(use_enable dane libdane) \
 109                 $(use_enable nls) \
 110                 $(use_enable openpgp openpgp-authentication) \
 111                 $(use_enable openssl openssl-compatibility) \
 112                 $(use_enable sslv2 ssl2-support) \
 113                 $(use_enable sslv3 ssl3-support) \
 114                 $(use_enable static-libs static) \
 115                 $(use_enable tls-heartbeat heartbeat-support) \
 116                 $(use_with idn libidn2) \
 117                 $(use_with idn) \
 118                 $(use_with pkcs11 p11-kit) \
 119                 $(use_with zlib) \
 120                 --with-unbound-root-key-file="${EPREFIX}/etc/dnssec/root-anchors.txt" \
 121                 --without-included-libtasn1 \
 122                 "${libconf[@]}"
 123 }
 124
 125 multilib_src_install_all() {
 126         einstalldocs
 127         prune_libtool_files --all
 128
 129         if use examples; then
 130                 docinto examples
 131                 dodoc doc/examples/*.c
 132         fi
 133 }