net-libs/gnet/gnet-2.0.8-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="yes"
   6 GNOME_TARBALL_SUFFIX="bz2"
   7
   8 inherit autotools eutils gnome2
   9
  10 DESCRIPTION="A simple network library"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/GNetLibrary"
  12
  13 LICENSE="LGPL-2"
  14 SLOT="2"
  15 KEYWORDS="~alpha amd64 hppa ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
  16 IUSE="test"
  17 RESTRICT="!test? ( test )"
  18
  19 # FIXME: automagic use of valgrind
  20 RDEPEND=">=dev-libs/glib-2.6:2"
  21 DEPEND="${RDEPEND}
  22         >=dev-libs/check-0.9.11
  23         >=dev-util/gtk-doc-am-1.2
  24         virtual/pkgconfig
  25 "
  26 # FIXME: check should only be needed with USE 'test', bug #349301
  27 #       test? ( >=dev-libs/check-0.9.7 )"
  28
  29 src_prepare() {
  30         # Do not leak main context reference, from master
  31         epatch "${FILESDIR}"/${PN}-2.0.8-context-leak.patch
  32
  33         # Fix usage of check framework, bug #296849, from master
  34         epatch "${FILESDIR}"/${PN}-2.0.8-check-usage-update.patch
  35
  36         # ifdef around network tests code, refs. bug #320759
  37         epatch "${FILESDIR}"/${PN}-2.0.8-network-tests.patch
  38
  39         # Do not hardcode glib patch in pkgconfig file, debian bug #652165
  40         epatch "${FILESDIR}"/${PN}-2.0.8-fix-pkgconfig-abuse.patch
  41
  42         # Compatibility with recent check releases, bug #498046
  43         epatch "${FILESDIR}"/${PN}-2.0.8-unittest-build.patch
  44
  45         # gnetlibrary.org has been adandoned, from master
  46         epatch "${FILESDIR}"/${PN}-2.0.8-test-existing-domain.patch
  47
  48         # Do not depend on a running HTTP server on port 80 for unittest
  49         epatch "${FILESDIR}"/${PN}-2.0.8-unittest-service.patch
  50
  51         # Do not pass silly cflags with USE=debug, bug #320759
  52         sed -i \
  53                 -e 's:-Werror::' \
  54                 -e '/AM_PROG_CC_STDC/d' \
  55                 -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:g' \
  56                 configure.ac || die
  57
  58         eautoreconf
  59         gnome2_src_prepare
  60 }
  61
  62 src_configure() {
  63         DOCS="AUTHORS BUGS ChangeLog HACKING NEWS README* TODO"
  64         # Do not enable network tests in an ebuild environment
  65         gnome2_src_configure \
  66                 --disable-static \
  67                 --disable-network-tests
  68 }