net-libs/farstream/farstream-0.2.8-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit gnome2 python-any-r1
   9
  10 DESCRIPTION="Audio/video conferencing framework specifically designed for instant messengers"
  11 HOMEPAGE="https://www.freedesktop.org/wiki/Software/Farstream"
  12 SRC_URI="https://freedesktop.org/software/farstream/releases/${PN}/${P}.tar.gz"
  13
  14 LICENSE="LGPL-2.1+"
  15 KEYWORDS="~alpha amd64 arm arm64 ~ia64 ppc ppc64 x86 ~amd64-linux ~x86-linux"
  16 IUSE="+introspection test upnp"
  17 SLOT="0.2/5" # .so version
  18
  19 # Tests need shmsink from gst-plugins-bad, which isn't packaged
  20 # FIXME: do an out-of-tree build for tests if USE=-msn
  21 RESTRICT="test"
  22
  23 COMMONDEPEND="
  24         >=media-libs/gstreamer-1.4:1.0
  25         >=media-libs/gst-plugins-base-1.4:1.0
  26         >=dev-libs/glib-2.32:2
  27         >=net-libs/libnice-0.1.8
  28         introspection? ( >=dev-libs/gobject-introspection-0.10.11:= )
  29         upnp? ( >=net-libs/gupnp-igd-0.2:= )
  30 "
  31 RDEPEND="${COMMONDEPEND}
  32         >=media-libs/gst-plugins-bad-1.4:1.0
  33         >=media-libs/gst-plugins-good-1.4:1.0
  34         media-plugins/gst-plugins-srtp:1.0
  35         media-plugins/gst-plugins-libnice:1.0
  36 "
  37 DEPEND="${COMMONDEPEND}
  38         ${PYTHON_DEPS}
  39         dev-util/glib-utils
  40         >=dev-util/gtk-doc-am-1.18
  41         virtual/pkgconfig
  42         test? (
  43                 media-libs/gst-plugins-base:1.0[vorbis]
  44                 media-libs/gst-plugins-good:1.0 )
  45 "
  46
  47 PATCHES=(
  48         "${FILESDIR}"/${PN}-0.2.8-make43.patch # remove when bumping and switching to Meson
  49 )
  50
  51 pkg_setup() {
  52         python-any-r1_pkg_setup
  53 }
  54
  55 src_configure() {
  56         plugins="fsrawconference,fsrtpconference,fsmsnconference,fsrtpxdata,fsfunnel,fsrtcpfilter,fsvideoanyrate"
  57         gnome2_src_configure \
  58                 --disable-static \
  59                 $(use_enable introspection) \
  60                 $(use_enable upnp gupnp) \
  61                 --with-plugins=${plugins}
  62 }
  63
  64 src_compile() {
  65         # Prevent sandbox violations, bug #539224
  66         # https://bugzilla.gnome.org/show_bug.cgi?id=744135
  67         # https://bugzilla.gnome.org/show_bug.cgi?id=744134
  68         addpredict /dev
  69         gnome2_src_compile
  70 }