net-libs/cvm/cvm-0.96-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="Credential Validation Modules by Bruce Guenter"
   9 HOMEPAGE="http://untroubled.org/cvm/"
  10 SRC_URI="http://untroubled.org/cvm/archive/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ppc ~sparc ~x86"
  15 IUSE="mysql postgres test vpopmail"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         dev-db/cdb:=
  20         >=dev-libs/bglibs-1.041:="
  21 DEPEND="${RDEPEND}
  22         mysql? ( dev-db/mysql-connector-c:0= )
  23         postgres? ( dev-db/postgresql[server] )
  24         vpopmail? ( net-mail/vpopmail )
  25         test? (
  26                 app-editors/vim
  27                 dev-db/sqlite
  28         )"
  29 # some of the testcases use
  30 # - ex/vi/xxd
  31 # - cdbmake
  32 # - sqlite
  33
  34 PATCHES=( "${FILESDIR}"/${PN}-0.96-fix-test-padding.patch )
  35
  36 src_prepare() {
  37         default
  38         # disable this test, as it breaks under Portage
  39         # and there is no easy fix
  40         sed -i.orig \
  41                 -e '/qmail-lookup-nodomain/,/^END_OF_TEST_RESULTS/d' \
  42                 "${S}"/tests.sh || die "sed failed"
  43         # Fix the vpopmail build
  44         sed -i.orig \
  45                 -e '/.\/ltload cvm-vchkpw/s,-lmysqlclient,,g' \
  46                 -e '/.\/ltload cvm-vchkpw/s,-L/usr/local/vpopmail/lib,,g' \
  47                 -e '/.\/ltload cvm-vchkpw/s,-L/var/vpopmail/lib,,g' \
  48                 -e '/.\/ltload cvm-vchkpw/s,-L/usr/local/lib/mysql,,g' \
  49                 -e '/.\/ltload cvm-vchkpw/s,\.la,.la `cat /var/vpopmail/etc/lib_deps`,g' \
  50                 "${S}"/Makefile \
  51                 || die "Failed to fix vpopmail linking parts of Makefile"
  52         sed -i.orig \
  53                 -e '/.\/compile cvm-vchkpw/s,$, `cat /var/vpopmail/etc/inc_deps`,g' \
  54                 "${S}"/Makefile \
  55                 || die "Failed to fix vpopmail compiling parts of Makefile"
  56 }
  57
  58 src_configure() {
  59         echo "/usr/include/bglibs" > conf-bgincs || die
  60         echo "/usr/$(get_libdir)/bglibs" > conf-bglibs || die
  61         echo "/usr/include" > conf-include || die
  62         echo "/usr/$(get_libdir)" > conf-lib || die
  63         echo "/usr/bin" > conf-bin || die
  64         echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
  65         echo "$(tc-getCC) ${LDFLAGS} -lcrypt" > conf-ld || die
  66 }
  67
  68 src_compile() {
  69         emake -j1
  70
  71         if use mysql; then
  72                 einfo "Building MySQL support"
  73                 emake -j1 mysql
  74         fi
  75
  76         if use postgres; then
  77                 einfo "Building Postgresql support"
  78                 emake -j1 pgsql
  79         fi
  80
  81         if use vpopmail; then
  82                 einfo "Building vpopmail support"
  83                 emake -j1 cvm-vchkpw
  84         fi
  85 }
  86
  87 src_test() {
  88         # bug 624384
  89         # the test suite tests stuff that isn't potentially enabled
  90         emake -j1 sqlite
  91         sh tests.sh || die "Testing Failed"
  92 }
  93
  94 src_install() {
  95         # Upstreams installer is incredibly broken
  96         dolib.a .libs/*.a
  97         dolib.so .libs/*.so.*
  98
  99         local i
 100         for i in a so; do
 101                 dosym libcvm-v2client.${i} /usr/$(get_libdir)/libcvm-client.${i}
 102         done
 103
 104         for i in {bench,test}client chain checkpassword pwfile qmail unix \
 105                         vmailmgr{,-local,-udp} v1{benchclient,checkpassword,testclient} \
 106                 ; do
 107                         dobin .libs/cvm-${i}
 108         done
 109         use mysql && dobin .libs/cvm-mysql{,-local,-udp}
 110         use postgres && dobin .libs/cvm-pgsql{,-local,-udp}
 111         use vpopmail && dobin .libs/cvm-vchkpw
 112
 113         insinto /usr/include/cvm
 114         doins {credentials,errors,facts,module,protocol,sasl,v1client,v2client}.h
 115         dosym v1client.h /usr/include/cvm/client.h
 116         dosym cvm/sasl.h /usr/include/cvm-sasl.h
 117
 118         dodoc ANNOUNCEMENT NEWS{,.sql,.vmailmgr}
 119         dodoc README{,.vchkpw,.vmailmgr}
 120         dodoc TODO VERSION ChangeLog*
 121         docinto html
 122         dodoc *.html
 123 }