net-irc/konversation/konversation-1.7.5-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_HANDBOOK="forceoptional"
   7 KFMIN=5.63.0
   8 QTMIN=5.12.3
   9 inherit ecm kde.org
  10
  11 DESCRIPTION="User friendly IRC Client"
  12 HOMEPAGE="https://konversation.kde.org
  13 https://kde.org/applications/internet/org.kde.konversation"
  14 SRC_URI="mirror://kde/stable/${PN}/${PV/_/-}/src/${P/_/-}.tar.xz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="5"
  18 KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
  19 IUSE="+crypt"
  20
  21 BDEPEND="sys-devel/gettext"
  22 DEPEND="
  23         >=dev-qt/qtdbus-${QTMIN}:5
  24         >=dev-qt/qtgui-${QTMIN}:5
  25         >=dev-qt/qtnetwork-${QTMIN}:5
  26         >=dev-qt/qtwidgets-${QTMIN}:5
  27         >=dev-qt/qtxml-${QTMIN}:5
  28         >=kde-frameworks/karchive-${KFMIN}:5
  29         >=kde-frameworks/kbookmarks-${KFMIN}:5=
  30         >=kde-frameworks/kcodecs-${KFMIN}:5
  31         >=kde-frameworks/kcompletion-${KFMIN}:5
  32         >=kde-frameworks/kconfig-${KFMIN}:5
  33         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  34         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  35         >=kde-frameworks/kcrash-${KFMIN}:5
  36         >=kde-frameworks/kdbusaddons-${KFMIN}:5
  37         >=kde-frameworks/kglobalaccel-${KFMIN}:5
  38         >=kde-frameworks/ki18n-${KFMIN}:5
  39         >=kde-frameworks/kiconthemes-${KFMIN}:5
  40         >=kde-frameworks/kidletime-${KFMIN}:5
  41         >=kde-frameworks/kio-${KFMIN}:5
  42         >=kde-frameworks/kitemviews-${KFMIN}:5
  43         >=kde-frameworks/knotifications-${KFMIN}:5
  44         >=kde-frameworks/knotifyconfig-${KFMIN}:5
  45         >=kde-frameworks/kparts-${KFMIN}:5
  46         >=kde-frameworks/kservice-${KFMIN}:5
  47         >=kde-frameworks/ktextwidgets-${KFMIN}:5
  48         >=kde-frameworks/kwallet-${KFMIN}:5
  49         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
  50         >=kde-frameworks/kwindowsystem-${KFMIN}:5
  51         >=kde-frameworks/kxmlgui-${KFMIN}:5
  52         media-libs/phonon[qt5(+)]
  53         crypt? ( app-crypt/qca:2[qt5(+)] )
  54 "
  55 RDEPEND="${DEPEND}
  56         crypt? ( app-crypt/qca:2[ssl] )
  57 "
  58
  59 PATCHES=(
  60         # 1.7 branch
  61         "${FILESDIR}"/${P}-fix-regex-for-cap-ack.patch
  62         "${FILESDIR}"/${P}-missing-header.patch
  63         "${FILESDIR}"/${P}-QElapsedTimer.patch
  64         "${FILESDIR}"/${P}-kf5windowsystem-5.63.patch
  65         # git master
  66         "${FILESDIR}"/${P}-kf5bookmarks-5.69.patch
  67         "${FILESDIR}"/${P}-unused-kemoticons.patch
  68         "${FILESDIR}"/${P}-qt-5.15.patch
  69 )
  70
  71 src_configure() {
  72         local mycmakeargs=(
  73                 $(cmake_use_find_package crypt Qca-qt5)
  74         )
  75
  76         ecm_src_configure
  77 }
  78
  79 src_install() {
  80         ecm_src_install
  81
  82         # Bug 616162
  83         insinto /etc/xdg
  84         doins "${FILESDIR}"/konversationrc
  85 }