net-irc/irssi/irssi-1.0.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils perl-module
   7
   8 # Keep for _rc compability
   9 MY_P="${P/_/-}"
  10
  11 DESCRIPTION="A modular textUI IRC client with IPv6 support"
  12 HOMEPAGE="https://irssi.org/"
  13 SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  18 IUSE="+perl selinux socks5 +proxy libressl"
  19
  20 CDEPEND="
  21         sys-libs/ncurses:0=
  22         >=dev-libs/glib-2.6.0
  23         !libressl? ( dev-libs/openssl:= )
  24         libressl? ( dev-libs/libressl:= )
  25         perl? ( dev-lang/perl:= )
  26         socks5? ( >=net-proxy/dante-1.1.18 )"
  27
  28 DEPEND="
  29         ${CDEPEND}
  30         virtual/pkgconfig"
  31
  32 RDEPEND="
  33         ${CDEPEND}
  34         selinux? ( sec-policy/selinux-irc )
  35         perl? ( !net-im/silc-client )"
  36
  37 RESTRICT="test"
  38
  39 S="${WORKDIR}/${MY_P}"
  40
  41 DOCS=( AUTHORS ChangeLog README.md TODO NEWS )
  42
  43 src_configure() {
  44         econf \
  45                 --with-perl-lib=vendor \
  46                 --enable-true-color \
  47                 $(use_with proxy) \
  48                 $(use_with perl) \
  49                 $(use_with socks5 socks)
  50 }
  51
  52 src_install() {
  53         emake DESTDIR="${D}" install
  54
  55         use perl && perl_delete_localpod
  56
  57         prune_libtool_files --modules
  58
  59         einstalldocs
  60 }