net-im/zoom/zoom-3.5.374815.0324-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit desktop eutils xdg-utils
   7
   8 DESCRIPTION="Video conferencing and web conferencing service"
   9 HOMEPAGE="https://zoom.us/"
  10 SRC_URI="amd64? ( https://zoom.us/client/${PV}/${PN}_x86_64.tar.xz -> ${P}_x86_64.tar.xz )
  11         x86? ( https://zoom.us/client/${PV}/${PN}_i686.tar.xz -> ${P}_i686.tar.xz )"
  12 S="${WORKDIR}/${PN}"
  13
  14 LICENSE="all-rights-reserved Apache-2.0" # Apache-2.0 for icon
  15 SLOT="0"
  16 KEYWORDS="-* ~amd64 ~x86"
  17 IUSE="pulseaudio"
  18 RESTRICT="mirror bindist strip"
  19
  20 RDEPEND="dev-libs/glib:2
  21         dev-libs/icu
  22         dev-qt/qtcore:5
  23         dev-qt/qtdbus:5
  24         dev-qt/qtdeclarative:5
  25         dev-qt/qtgraphicaleffects:5
  26         dev-qt/qtgui:5
  27         dev-qt/qtnetwork:5
  28         dev-qt/qtpositioning:5
  29         dev-qt/qtprintsupport:5
  30         dev-qt/qtquickcontrols:5[widgets]
  31         dev-qt/qtscript:5
  32         dev-qt/qtwebchannel:5
  33         dev-qt/qtwebengine:5
  34         dev-qt/qtwidgets:5
  35         media-libs/libglvnd
  36         media-libs/libjpeg-turbo
  37         media-sound/mpg123
  38         sys-apps/dbus
  39         sys-apps/util-linux
  40         x11-libs/libX11
  41         x11-libs/libxcb
  42         x11-libs/libXext
  43         x11-libs/libXfixes
  44         x11-libs/libXtst
  45         x11-libs/xcb-util-image
  46         x11-libs/xcb-util-keysyms
  47         pulseaudio? ( media-sound/pulseaudio )
  48         !pulseaudio? ( media-libs/alsa-lib )"
  49
  50 BDEPEND="!pulseaudio? ( dev-util/bbe )"
  51
  52 QA_PREBUILT="opt/zoom/*"
  53
  54 src_prepare() {
  55         default
  56         if ! use pulseaudio; then
  57                 # For some strange reason, zoom cannot use any ALSA sound devices if
  58                 # it finds libpulse. This causes breakage if media-sound/apulse[sdk]
  59                 # is installed. So, force zoom to ignore libpulse.
  60                 bbe -e 's/libpulse.so/IgNoRePuLsE/' zoom >zoom.tmp || die
  61                 mv zoom.tmp zoom || die
  62         fi
  63 }
  64
  65 src_install() {
  66         insinto /opt/zoom
  67         exeinto /opt/zoom
  68         doins -r json sip timezones translations
  69         doins *.pcm *.pem *.sh Embedded.properties version.txt
  70         use amd64 && doins icudtl.dat
  71         doexe zoom{,.sh,linux} zopen ZoomLauncher
  72         dosym {"../../usr/$(get_libdir)",/opt/zoom}/libmpg123.so
  73         dosym {"../../usr/$(get_libdir)",/opt/zoom}/libturbojpeg.so #715106
  74
  75         make_wrapper zoom ./zoom /opt/zoom
  76         make_desktop_entry "zoom %U" Zoom zoom-videocam "" \
  77                 "MimeType=x-scheme-handler/zoommtg;application/x-zoom;"
  78         # The tarball doesn't contain an icon, so take a generic camera icon
  79         # from https://github.com/google/material-design-icons, modified to be
  80         # white on a blue background
  81         doicon "${FILESDIR}"/zoom-videocam.{svg,xpm}
  82 }
  83
  84 pkg_postinst() {
  85         xdg_desktop_database_update
  86 }
  87
  88 pkg_postrm() {
  89         xdg_desktop_database_update
  90 }