net-im/minbif/minbif-1.0.5-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils user
   7
   8 DESCRIPTION="IRC gateway to IM networks"
   9 HOMEPAGE="https://symlink.me/projects/minbif/wiki/"
  10 SRC_URI="https://symlink.me/attachments/download/148/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm x86"
  15 IUSE="gnutls +imlib +libcaca pam xinetd"
  16 REQUIRED_USE="
  17         libcaca? ( imlib )
  18 "
  19
  20 DEPEND="
  21         >=net-im/pidgin-2.6
  22         gnutls? ( net-libs/gnutls )
  23         imlib? ( media-libs/imlib2 )
  24         libcaca? (
  25                 media-libs/imlib2
  26                 media-libs/libcaca
  27         )
  28         pam? ( sys-libs/pam )
  29 "
  30 RDEPEND="${DEPEND}
  31         virtual/logger
  32         xinetd? ( sys-apps/xinetd )
  33 "
  34
  35 PATCHES=(
  36         "${FILESDIR}/${PN}-1.0.5-glib-single-includes.patch"
  37         "${FILESDIR}/${PN}-1.0.5-gcc47.patch"
  38         "${FILESDIR}/${PN}-1.0.5-rename-imlib-load-error.patch"
  39 )
  40
  41 pkg_setup() {
  42         enewgroup minbif
  43         enewuser minbif -1 -1 /var/lib/minbif minbif
  44 }
  45
  46 src_prepare() {
  47         cmake-utils_src_prepare
  48
  49         sed -i "s/-Werror//g" CMakeLists.txt || die "sed failed"
  50
  51         sed -i "s#share/doc/minbif#share/doc/${P}#" \
  52                 CMakeLists.txt || die "sed failed"
  53
  54         if use xinetd; then
  55                 sed -i "s/type\s=\s[0-9]/type = 0/" \
  56                         minbif.conf || die "sed failed"
  57         fi
  58 }
  59
  60 src_configure() {
  61         local mycmakeargs=(
  62                 -DCONF_PREFIX="${EPREFIX}"/etc/minbif
  63                 -DENABLE_VIDEO=OFF
  64                 -DENABLE_TLS=$(usex gnutls)
  65                 -DENABLE_IMLIB=$(usex imlib)
  66                 -DENABLE_CACA=$(usex libcaca)
  67                 -DENABLE_PAM=$(usex pam)
  68         )
  69
  70         cmake-utils_src_configure
  71 }
  72
  73 src_install() {
  74         cmake-utils_src_install
  75         keepdir /var/lib/minbif
  76         fperms 700 /var/lib/minbif
  77         fowners minbif:minbif /var/lib/minbif
  78
  79         doman man/minbif.8
  80
  81         if use xinetd; then
  82                 insinto /etc/xinetd.d
  83                 newins doc/minbif.xinetd minbif
  84         fi
  85
  86         newinitd "${FILESDIR}"/minbif.initd minbif
  87
  88         dodir /usr/share/minbif
  89         insinto /usr/share/minbif
  90         doins -r scripts
  91 }