net-im/empathy/empathy-3.12.14.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 PYTHON_COMPAT=( python3_6 )
   7
   8 inherit gnome2 python-any-r1 virtualx
   9
  10 DESCRIPTION="Telepathy instant messaging and video/audio call client for GNOME"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Empathy"
  12
  13 LICENSE="GPL-2 CC-BY-SA-3.0 FDL-1.3 LGPL-2.1"
  14 SLOT="0"
  15 IUSE="debug +geolocation gnome gnome-online-accounts +map spell test +v4l"
  16 RESTRICT="!test? ( test )"
  17 KEYWORDS="~alpha amd64 ~arm ~ppc ~ppc64 x86 ~x86-linux"
  18
  19 # False positives caused by nested configure scripts
  20 QA_CONFIGURE_OPTIONS=".*"
  21
  22 # gdk-pixbuf and pango extensively used in libempathy-gtk
  23 COMMON_DEPEND="
  24         >=dev-libs/glib-2.48:2[dbus]
  25         x11-libs/gdk-pixbuf:2
  26         >=x11-libs/gtk+-3.9.4:3
  27         x11-libs/pango
  28         >=dev-libs/dbus-glib-0.51
  29         >=dev-libs/folks-0.9.5:=[telepathy]
  30         dev-libs/libgee:0.8=
  31         >=app-crypt/libsecret-0.5
  32         >=media-libs/libcanberra-0.25[gtk3]
  33         >=net-libs/webkit-gtk-2.10:4
  34         >=x11-libs/libnotify-0.7:=
  35
  36         media-libs/gstreamer:1.0
  37         >=media-libs/clutter-1.10.0:1.0
  38         >=media-libs/clutter-gtk-1.1.2:1.0
  39         media-libs/clutter-gst:3.0
  40         >=media-libs/cogl-1.14:1.0=
  41
  42         net-libs/farstream:0.2=
  43         >=net-libs/telepathy-farstream-0.6.0:=
  44         >=net-libs/telepathy-glib-0.23.2
  45         >=net-im/telepathy-logger-0.8.0:=
  46
  47         app-crypt/gcr[gtk]
  48         dev-libs/libxml2:2
  49         gnome-base/gsettings-desktop-schemas
  50         media-sound/pulseaudio[glib]
  51         net-libs/libsoup:2.4
  52         x11-libs/libX11
  53
  54         geolocation? (
  55                 >=app-misc/geoclue-2.1:2.0
  56                 >=sci-geosciences/geocode-glib-3.10 )
  57         gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.5.1:= )
  58         map? (
  59                 >=media-libs/clutter-1.7.14:1.0
  60                 >=media-libs/clutter-gtk-0.90.3:1.0
  61                 >=media-libs/libchamplain-0.12.1:0.12[gtk] )
  62         spell? (
  63                 >=app-text/enchant-1.2:0
  64                 >=app-text/iso-codes-0.35 )
  65         v4l? (
  66                 dev-libs/libgudev:=
  67                 media-plugins/gst-plugins-v4l2:1.0
  68                 >=media-video/cheese-3.4:= )
  69 "
  70
  71 # >=empathy-3.4 is incompatible with telepathy-rakia-0.6, bug #403861
  72 RDEPEND="${COMMON_DEPEND}
  73         media-libs/gst-plugins-base:1.0
  74         net-im/telepathy-connection-managers
  75         !<net-voip/telepathy-rakia-0.7
  76         x11-themes/adwaita-icon-theme
  77         gnome? ( gnome-extra/gnome-contacts )
  78 "
  79 DEPEND="${COMMON_DEPEND}
  80         ${PYTHON_DEPS}
  81         dev-libs/libxml2:2
  82         dev-libs/libxslt
  83         >=dev-util/intltool-0.50.0
  84         dev-util/itstool
  85         virtual/pkgconfig
  86         test? (
  87                 sys-apps/grep
  88                 >=dev-libs/check-0.9.4 )
  89 "
  90 PDEPEND=">=net-im/telepathy-mission-control-5.14"
  91
  92 pkg_setup() {
  93         python-any-r1_pkg_setup
  94         export PYTHONIOENCODING=UTF-8 # See bug 489774
  95 }
  96
  97 src_configure() {
  98         DOCS="CONTRIBUTORS AUTHORS ChangeLog NEWS README"
  99         gnome2_src_configure \
 100                 --disable-coding-style-checks \
 101                 --disable-static \
 102                 --disable-ubuntu-online-accounts \
 103                 --enable-gst-1.0 \
 104                 $(use_enable debug) \
 105                 $(use_enable geolocation geocode) \
 106                 $(use_enable geolocation location) \
 107                 $(use_enable gnome-online-accounts goa) \
 108                 $(use_enable map) \
 109                 $(use_enable spell) \
 110                 $(use_enable v4l gudev) \
 111                 $(use_with v4l cheese)
 112 }
 113
 114 src_test() {
 115         dbus-launch virtx emake check #504516
 116 }