net-ftp/gftp/gftp-2.0.19-r3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 inherit gnome2
   7
   8 DESCRIPTION="Gnome based FTP Client"
   9 SRC_URI="http://www.gftp.org/${P}.tar.bz2"
  10 HOMEPAGE="http://www.gftp.org"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 ~ppc ~ppc64 ~sparc x86 ~x86-fbsd"
  15 IUSE="gtk libressl ssl"
  16
  17 RDEPEND="
  18         dev-libs/glib:2
  19         sys-devel/gettext
  20         sys-libs/ncurses:0=
  21         sys-libs/readline:0
  22         gtk? ( x11-libs/gtk+:2 )
  23         ssl? (
  24                 !libressl? ( dev-libs/openssl:0= )
  25                 libressl? ( dev-libs/libressl:0= ) )
  26 "
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29 "
  30
  31 PATCHES=(
  32         # Fix SIGSEGV for gftp_expand_path function
  33         "${FILESDIR}/${P}-${PN}-expand-path-sigsegv.patch"
  34
  35         # https://bugzilla.gnome.org/show_bug.cgi?id=740785
  36         "${FILESDIR}/${P}-desktop.patch"
  37 )
  38
  39 src_configure() {
  40         gnome2_src_configure \
  41                 $(use_enable gtk gtkport) \
  42                 $(use_enable ssl)
  43 }
  44
  45 src_install() {
  46         gnome2_src_install
  47         dodoc docs/USERS-GUIDE
  48 }