net-ftp/ftp/ftp-0.17.23.0.2.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 inherit eutils toolchain-funcs flag-o-matic versionator
   8
   9 PATCH_VER="2"
  10 MY_PN="netkit-ftp"
  11 MY_PV="$(get_version_component_range 1-2)"
  12 MY_P="netkit-${PN}-${MY_PV}"
  13 DEB_PN="${MY_PN}-ssl"
  14 DEB_PV="$(get_version_component_range 1-3)+$(get_version_component_range 4-5)-$(get_version_component_range 6)"
  15 DESCRIPTION="Standard Linux FTP client"
  16 HOMEPAGE="http://www.hcs.harvard.edu/~dholland/computers/netkit.html"
  17 SRC_URI="ftp://sunsite.unc.edu/pub/Linux/system/network/netkit/${MY_P}.tar.gz
  18         mirror://debian/pool/main/n/${DEB_PN}/${DEB_PN}_${DEB_PV}.debian.tar.gz
  19         mirror://gentoo/${MY_P}-patches-${PATCH_VER}.tar.bz2"
  20
  21 LICENSE="BSD"
  22 SLOT="0"
  23 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
  24 IUSE="ipv6 readline ssl"
  25
  26 RDEPEND=">=sys-libs/ncurses-5.2:=
  27         readline? ( sys-libs/readline:0= )
  28         ssl? ( dev-libs/openssl:0= )"
  29 DEPEND="${RDEPEND}"
  30
  31 S=${WORKDIR}/${MY_P}
  32
  33 src_prepare() {
  34         EPATCH_FORCE="yes" EPATCH_SUFFIX="diff" epatch "${WORKDIR}"/debian/patches
  35         EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/patch
  36         sed -i \
  37                 -e 's:echo -n:printf %s :' \
  38                 configure || die
  39 }
  40
  41 src_configure() {
  42         append-lfs-flags #101038
  43         tc-export CC
  44         # not an autoconf script
  45         ./configure \
  46                 --prefix=/usr \
  47                 $(use_enable ipv6) \
  48                 $(use_enable readline) \
  49                 $(use_enable ssl) \
  50                 || die
  51 }
  52
  53 src_install() {
  54         dobin ftp/ftp
  55         doman ftp/ftp.1 ftp/netrc.5
  56         dodoc ChangeLog README BUGS
  57 }