net-ftp/filezilla/filezilla-3.14.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 WX_GTK_VER="3.0"
   8
   9 inherit autotools eutils flag-o-matic multilib wxwidgets
  10
  11 MY_PV=${PV/_/-}
  12 MY_P="FileZilla_${MY_PV}"
  13
  14 DESCRIPTION="FTP client with lots of useful features and an intuitive interface"
  15 HOMEPAGE="http://filezilla-project.org/"
  16 SRC_URI="mirror://sourceforge/${PN}/${MY_P}_src.tar.bz2"
  17
  18 LICENSE="GPL-2"
  19 SLOT="0"
  20 KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
  21 IUSE="aqua dbus nls test"
  22
  23 RDEPEND=">=app-eselect/eselect-wxwidgets-0.7-r1
  24         >=dev-db/sqlite-3.7
  25         net-dns/libidn
  26         >=net-libs/gnutls-3.1.12
  27         aqua? ( >=x11-libs/wxGTK-3.0.2.0-r1:3.0[aqua] )
  28         !aqua? ( >=x11-libs/wxGTK-3.0.2.0-r1:3.0[X] x11-misc/xdg-utils )
  29         dbus? ( sys-apps/dbus )"
  30 #       >=dev-libs/pugixml-1.5
  31 DEPEND="${RDEPEND}
  32         virtual/pkgconfig
  33         >=sys-devel/libtool-1.4
  34         nls? ( >=sys-devel/gettext-0.11 )
  35         test? ( dev-util/cppunit )"
  36
  37 S="${WORKDIR}"/${PN}-${MY_PV}
  38
  39 pkg_pretend() {
  40         if [[ ${MERGE_TYPE} != binary ]]; then
  41                 if ! test-flag-CXX -std=c++14; then
  42                         eerror "${P} requires C++14-capable C++ compiler. Your current compiler"
  43                         eerror "does not seem to support -std=c++14 option. Please upgrade your compiler"
  44                         eerror "to gcc-4.9 or an equivalent version supporting C++14."
  45                         die "Currently active compiler does not support -std=c++14"
  46                 fi
  47         fi
  48 }
  49
  50 src_prepare() {
  51         epatch "${FILESDIR}"/${PN}-3.10.2-debug.patch
  52         eautoreconf
  53 }
  54
  55 src_configure() {
  56         # system pugixml lacks long long ops support, use builtin for now
  57         econf $(use_with dbus) $(use_enable nls locales) \
  58                 --with-pugixml=builtin \
  59                 --disable-autoupdatecheck
  60 }
  61
  62 src_install() {
  63         emake DESTDIR="${D}" install
  64
  65         doicon src/interface/resources/48x48/${PN}.png
  66
  67         dodoc AUTHORS ChangeLog NEWS
  68
  69         if use aqua ; then
  70                 cat > "${T}/${PN}" <<-EOF || die
  71                         #!${EPREFIX}/bin/bash
  72                         open "${EPREFIX}"/Applications/FileZilla.app
  73                 EOF
  74                 rm "${ED}/usr/bin/${PN}" || die
  75                 dobin "${T}/${PN}"
  76                 insinto /Applications
  77                 doins -r "${S}"/FileZilla.app
  78         fi
  79 }