net-dialup/rp-pppoe/rp-pppoe-3.13.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit autotools flag-o-matic readme.gentoo-r1
   7
   8 PPP_P="ppp-2.4.7"
   9
  10 DESCRIPTION="A user-mode PPPoE client and server suite for Linux"
  11 HOMEPAGE="https://www.roaringpenguin.com/products/pppoe"
  12 SRC_URI="https://dianne.skoll.ca/projects/rp-pppoe/download/${P}.tar.gz
  13         https://www.samba.org/ftp/pub/ppp/${PPP_P}.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
  18 IUSE="tk"
  19
  20 RDEPEND="
  21         net-dialup/ppp:=
  22         tk? ( dev-lang/tk:= )
  23 "
  24 DEPEND=">=sys-kernel/linux-headers-2.6.25
  25         ${RDEPEND}"
  26
  27 DOC_CONTENTS="Use pppoe-setup to configure your dialup connection"
  28
  29 pkg_setup() {
  30         # This is needed in multiple phases
  31         PPPD_VER=$(best_version net-dialup/ppp)
  32         PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
  33         PPPD_VER=${PPPD_VER%%-*} #reduce it to ${PV}
  34 }
  35
  36 PATCHES=(
  37         # Patch to enable integration of pppoe-start and pppoe-stop with
  38         # baselayout-1.11.x so that the pidfile can be found reliably per interface
  39         "${FILESDIR}/${PN}-3.10-gentoo-netscripts.patch"
  40
  41         "${FILESDIR}/${PN}-3.10-username-charset.patch" # bug 82410
  42         "${FILESDIR}/${PN}-3.10-plugin-options.patch"
  43         "${FILESDIR}/${PN}-3.13-autotools.patch"
  44         "${FILESDIR}/${PN}-3.10-posix-source-sigaction.patch"
  45         "${FILESDIR}/${PN}-3.11-gentoo.patch"
  46         "${FILESDIR}/${PN}-3.11-kmode.patch" #364941
  47         "${FILESDIR}/${PN}-3.13-linux-headers.patch"
  48         "${FILESDIR}/${PN}-3.12-ifconfig-path.patch" #602344
  49 )
  50
  51 src_prepare() {
  52         if has_version '<sys-kernel/linux-headers-2.6.35' ; then
  53                 PATCHES+=(
  54                         "${FILESDIR}/${PN}-3.10-linux-headers.patch" #334197
  55                 )
  56         fi
  57
  58         default
  59
  60         cd "${S}"/src || die
  61         eautoreconf
  62 }
  63
  64 src_configure() {
  65         addpredict /dev/ppp
  66
  67         cd "${S}/src" || die
  68         # PPPD_VER variable is required for correct pppd detection
  69         # This was added through the rp-pppoe-*-autotools.patch
  70         econf PPPD_VER="${PPPD_VER}" --enable-plugin=../../ppp-${PPPD_VER}
  71 }
  72
  73 src_compile() {
  74         cd "${S}/src" || die
  75         emake
  76
  77         if use tk; then
  78                 emake -C "${S}/gui"
  79         fi
  80 }
  81
  82 src_install() {
  83         cd "${S}/src" || die
  84         emake DESTDIR="${D}" install #docdir=/usr/share/doc/${PF} install
  85
  86         #Don't use compiled rp-pppoe plugin - see pkg_preinst below
  87         local pppoe_plugin="${ED}/etc/ppp/plugins/rp-pppoe.so"
  88         if [ -f "${pppoe_plugin}" ] ; then
  89                 rm "${pppoe_plugin}" || die
  90         fi
  91
  92         if use tk; then
  93                 emake -C "${S}/gui" \
  94                         DESTDIR="${D}" \
  95                         datadir=/usr/share/doc/${PF}/ \
  96                         install
  97                 dosym doc/${PF}/tkpppoe /usr/share/tkpppoe
  98         fi
  99
 100         newinitd "${FILESDIR}"/pppoe-server.initd pppoe-server
 101         newconfd "${FILESDIR}"/pppoe-server.confd pppoe-server
 102
 103         readme.gentoo_create_doc
 104 }
 105
 106 pkg_preinst() {
 107         # Use the rp-pppoe plugin that comes with net-dialup/pppd
 108         if [ -n "${PPPD_VER}" ] && [ -f "${EROOT}/usr/lib/pppd/${PPPD_VER}/rp-pppoe.so" ] ; then
 109                 dosym ../../../usr/lib/pppd/${PPPD_VER}/rp-pppoe.so /etc/ppp/plugins/rp-pppoe.so
 110         fi
 111 }