net-dialup/rp-pppoe/rp-pppoe-3.12-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eutils flag-o-matic autotools readme.gentoo-r1
   7
   8 PPP_P="ppp-2.4.7"
   9
  10 DESCRIPTION="A user-mode PPPoE client and server suite for Linux"
  11 HOMEPAGE="https://www.roaringpenguin.com/products/pppoe"
  12 SRC_URI="http://www.roaringpenguin.com/files/download/${P}.tar.gz
  13         https://www.samba.org/ftp/pub/ppp/${PPP_P}.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~mips ppc ppc64 ~sh sparc x86"
  18 IUSE="tk"
  19
  20 RDEPEND="
  21         net-dialup/ppp:=
  22         tk? ( dev-lang/tk:= )
  23 "
  24 DEPEND=">=sys-kernel/linux-headers-2.6.25
  25         ${RDEPEND}"
  26
  27 DOC_CONTENTS="Use pppoe-setup to configure your dialup connection"
  28
  29 pkg_setup() {
  30         # This is needed in multiple phases
  31         PPPD_VER=$(best_version net-dialup/ppp)
  32         PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
  33         PPPD_VER=${PPPD_VER%%-*} #reduce it to ${PV}
  34 }
  35
  36 PATCHES=(
  37         # Patch to enable integration of pppoe-start and pppoe-stop with
  38         # baselayout-1.11.x so that the pidfile can be found reliably per interface
  39         "${FILESDIR}/${PN}-3.10-gentoo-netscripts.patch"
  40
  41         "${FILESDIR}/${PN}-3.10-username-charset.patch" # bug 82410
  42         "${FILESDIR}/${PN}-3.10-plugin-options.patch"
  43         "${FILESDIR}/${PN}-3.10-autotools.patch"
  44         "${FILESDIR}/${PN}-3.10-posix-source-sigaction.patch"
  45         "${FILESDIR}/${PN}-3.11-gentoo.patch"
  46         "${FILESDIR}/${PN}-3.11-kmode.patch" #364941
  47         "${FILESDIR}/${PN}-3.12-linux-headers.patch"
  48         "${FILESDIR}/${PN}-3.12-ifconfig-path.patch" #602344
  49 )
  50
  51 src_prepare() {
  52         if has_version '<sys-kernel/linux-headers-2.6.35' ; then
  53                 PATCHES+=(
  54                         "${FILESDIR}/${PN}-3.10-linux-headers.patch" #334197
  55                 )
  56         fi
  57
  58         default
  59
  60         cd "${S}"/src || die
  61         eautoreconf
  62 }
  63
  64 src_configure() {
  65         addpredict /dev/ppp
  66
  67         cd "${S}/src" || die
  68         econf --enable-plugin=../../ppp-${PPPD_VER}
  69 }
  70
  71 src_compile() {
  72         cd "${S}/src" || die
  73         emake
  74
  75         if use tk; then
  76                 emake -C "${S}/gui"
  77         fi
  78 }
  79
  80 src_install() {
  81         cd "${S}/src" || die
  82         emake DESTDIR="${D}" docdir=/usr/share/doc/${PF} install
  83
  84         #Don't use compiled rp-pppoe plugin - see pkg_preinst below
  85         local pppoe_plugin="${D}/etc/ppp/plugins/rp-pppoe.so"
  86         if [ -f "${pppoe_plugin}" ] ; then
  87                 rm "${pppoe_plugin}" || die
  88         fi
  89
  90         if use tk; then
  91                 emake -C "${S}/gui" \
  92                         DESTDIR="${D}" \
  93                         datadir=/usr/share/doc/${PF}/ \
  94                         install
  95                 dosym /usr/share/doc/${PF}/tkpppoe /usr/share/tkpppoe
  96         fi
  97
  98         readme.gentoo_create_doc
  99 }
 100
 101 pkg_preinst() {
 102         # Use the rp-pppoe plugin that comes with net-dialup/pppd
 103         if [ -n "${PPPD_VER}" ] && [ -f "${ROOT}/usr/lib/pppd/${PPPD_VER}/rp-pppoe.so" ] ; then
 104                 dosym /usr/lib/pppd/${PPPD_VER}/rp-pppoe.so /etc/ppp/plugins/rp-pppoe.so
 105         fi
 106 }