net-dialup/rp-l2tp/rp-l2tp-0.4-r4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="User-space implementation of L2TP for Linux and other UNIX systems"
   8 HOMEPAGE="https://sourceforge.net/projects/rp-l2tp/"
   9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 KEYWORDS="amd64 ~ppc x86"
  13 SLOT="0"
  14
  15 PATCHES=(
  16         "${FILESDIR}/${P}-gentoo.patch"
  17         "${FILESDIR}/${P}-flags.patch"
  18         "${FILESDIR}/${P}-build.patch"
  19         "${FILESDIR}/${P}-parallel-build.patch"
  20 )
  21
  22 src_prepare() {
  23         tc-export AR CC RANLIB
  24         default
  25 }
  26
  27 src_install() {
  28         emake RPM_INSTALL_ROOT="${D}" install
  29
  30         einstalldocs
  31         newdoc l2tp.conf rp-l2tpd.conf
  32         docinto libevent
  33         dodoc libevent/Doc/*
  34         docompress -x "/usr/share/doc/${PF}/libevent"
  35
  36         newinitd "${FILESDIR}/rp-l2tpd-init" rp-l2tpd
  37 }