net-dialup/minicom/minicom-2.7.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools
   6
   7 STUPID_NUM="3977"
   8 DESCRIPTION="Serial Communication Program"
   9 HOMEPAGE="https://alioth.debian.org/projects/minicom"
  10 SRC_URI="https://alioth.debian.org/frs/download.php/file/${STUPID_NUM}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux"
  15 IUSE="nls"
  16
  17 COMMON_DEPEND="sys-libs/ncurses:="
  18 DEPEND="${COMMON_DEPEND}
  19         nls? ( sys-devel/gettext )"
  20 RDEPEND="${COMMON_DEPEND}
  21         net-dialup/lrzsz"
  22
  23 DOCS="AUTHORS ChangeLog NEWS README doc/minicom.FAQ"
  24 S="${WORKDIR}/${PN}-2.7" # 2.7.1 specific
  25
  26 PATCHES=(
  27         "${FILESDIR}"/${PN}-2.3-gentoo-runscript.patch
  28         "${FILESDIR}"/${PN}-2.7-lockdir.patch
  29 )
  30
  31 src_prepare() {
  32         default
  33         mv "${S}"/configure.{in,ac}
  34         eautoreconf
  35 }
  36
  37 src_configure() {
  38         # Lockdir must exist if not manually specified.
  39         # /var/lock is created by openrc.
  40         LOCKDIR=/var/lock
  41         econf \
  42                 --sysconfdir="${EPREFIX}"/etc/${PN} \
  43                 --enable-lock-dir="${LOCKDIR}" \
  44                 $(use_enable nls)
  45 }
  46
  47 src_install() {
  48         default
  49         insinto /etc/minicom
  50         doins "${FILESDIR}"/minirc.dfl
  51 }
  52
  53 pkg_preinst() {
  54         [[ -s ${EROOT}/etc/minicom/minirc.dfl ]] && rm -f "${ED}"/etc/minicom/minirc.dfl
  55 }