net-dialup/linux-atm/linux-atm-2.5.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils flag-o-matic libtool linux-info
   7
   8 DESCRIPTION="Tools for ATM"
   9 HOMEPAGE="http://linux-atm.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 ~riscv s390 sh sparc x86"
  15 IUSE="static-libs"
  16
  17 RDEPEND=""
  18 DEPEND="virtual/yacc"
  19
  20 RESTRICT="test"
  21
  22 DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS )
  23
  24 CONFIG_CHECK="~ATM"
  25
  26 src_prepare() {
  27         epatch "${FILESDIR}"/${P}-headers.patch
  28
  29         sed -i '/#define _LINUX_NETDEVICE_H/d' \
  30                 src/arpd/*.c || die "sed command on arpd/*.c files failed"
  31
  32         elibtoolize
  33 }
  34
  35 src_configure() {
  36         append-flags -fno-strict-aliasing
  37
  38         econf $(use_enable static-libs static)
  39 }
  40
  41 src_install() {
  42         default
  43         prune_libtool_files
  44         dodoc doc/README* doc/atm*
  45 }