net-analyzer/vnstat/vnstat-1.17.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs user
   6
   7 DESCRIPTION="Console-based network traffic monitor that keeps statistics of network usage"
   8 HOMEPAGE="http://humdi.net/vnstat/"
   9 SRC_URI="http://humdi.net/vnstat/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="amd64 arm hppa ppc ppc64 sparc x86"
  14 IUSE="gd selinux test"
  15
  16 COMMON_DEPEND="
  17         gd? ( media-libs/gd[png] )
  18 "
  19 DEPEND="
  20         ${COMMON_DEPEND}
  21         test? ( dev-libs/check )
  22 "
  23 RDEPEND="
  24         ${COMMON_DEPEND}
  25         selinux? ( sec-policy/selinux-vnstatd )
  26 "
  27
  28 pkg_setup() {
  29         enewgroup vnstat
  30         enewuser vnstat -1 -1 /dev/null vnstat
  31 }
  32
  33 src_prepare() {
  34         default
  35
  36         tc-export CC
  37
  38         sed -i \
  39                 -e 's|vnstat[.]log|vnstatd.log|' \
  40                 -e 's|vnstat[.]pid|vnstatd/vnstatd.pid|' \
  41                 -e 's|/var/run|/run|' \
  42                 cfg/${PN}.conf || die
  43         sed -i \
  44                 -e '/PIDFILE/s|/var/run|/run|' \
  45                 src/common.h || die
  46 }
  47
  48 src_compile() {
  49         emake ${PN} ${PN}d $(usex gd ${PN}i '')
  50 }
  51
  52 src_install() {
  53         use gd && dobin vnstati
  54         dobin vnstat vnstatd
  55
  56         exeinto /etc/cron.hourly
  57         newexe "${FILESDIR}"/vnstat.cron vnstat
  58
  59         insinto /etc
  60         doins cfg/vnstat.conf
  61         fowners root:vnstat /etc/vnstat.conf
  62
  63         newconfd "${FILESDIR}"/vnstatd.confd vnstatd
  64         newinitd "${FILESDIR}"/vnstatd.initd-r1 vnstatd
  65
  66         use gd && doman man/vnstati.1
  67         doman man/vnstat.1 man/vnstatd.1
  68
  69         newdoc INSTALL README.setup
  70         dodoc CHANGES README UPGRADE FAQ examples/vnstat.cgi
  71 }