net-analyzer/vnstat/vnstat-1.17-r2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit systemd user
   6
   7 DESCRIPTION="Console-based network traffic monitor that keeps statistics of network usage"
   8 HOMEPAGE="http://humdi.net/vnstat/"
   9 SRC_URI="http://humdi.net/vnstat/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
  14 IUSE="gd selinux test"
  15
  16 COMMON_DEPEND="
  17         gd? ( media-libs/gd[png] )
  18 "
  19 DEPEND="
  20         ${COMMON_DEPEND}
  21         test? ( dev-libs/check )
  22 "
  23 RDEPEND="
  24         ${COMMON_DEPEND}
  25         selinux? ( sec-policy/selinux-vnstatd )
  26 "
  27 PATCHES=(
  28         "${FILESDIR}"/${PN}-1.17-conf.patch
  29         "${FILESDIR}"/${PN}-1.17-run.patch
  30 )
  31
  32 pkg_setup() {
  33         enewgroup vnstat
  34         enewuser vnstat -1 -1 /var/lib/vnstat vnstat
  35 }
  36
  37 src_compile() {
  38         emake ${PN} ${PN}d $(usex gd ${PN}i '')
  39 }
  40
  41 src_install() {
  42         use gd && dobin vnstati
  43         dobin vnstat vnstatd
  44
  45         exeinto /usr/share/${PN}
  46         newexe "${FILESDIR}"/vnstat.cron-r1 vnstat.cron
  47
  48         insinto /etc
  49         doins cfg/vnstat.conf
  50         fowners root:vnstat /etc/vnstat.conf
  51
  52         keepdir /var/lib/vnstat
  53         fowners vnstat:vnstat /var/lib/vnstat
  54
  55         newconfd "${FILESDIR}"/vnstatd.confd-r1 vnstatd
  56         newinitd "${FILESDIR}"/vnstatd.initd-r2 vnstatd
  57
  58         systemd_newunit "${FILESDIR}"/vnstatd.systemd vnstatd.service
  59         systemd_newtmpfilesd "${FILESDIR}"/vnstatd.tmpfile vnstatd.conf
  60
  61         use gd && doman man/vnstati.1
  62         doman man/vnstat.1 man/vnstatd.1
  63
  64         newdoc INSTALL README.setup
  65         dodoc CHANGES README UPGRADE FAQ examples/vnstat.cgi
  66 }