net-analyzer/vnstat/vnstat-1.17-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 inherit systemd toolchain-funcs user
   6
   7 DESCRIPTION="Console-based network traffic monitor that keeps statistics of network usage"
   8 HOMEPAGE="http://humdi.net/vnstat/"
   9 SRC_URI="http://humdi.net/vnstat/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
  14 IUSE="gd selinux test"
  15
  16 COMMON_DEPEND="
  17         gd? ( media-libs/gd[png] )
  18 "
  19 DEPEND="
  20         ${COMMON_DEPEND}
  21         test? ( dev-libs/check )
  22 "
  23 RDEPEND="
  24         ${COMMON_DEPEND}
  25         selinux? ( sec-policy/selinux-vnstatd )
  26 "
  27 PATCHES=(
  28         "${FILESDIR}"/${PN}-1.17-limit.patch
  29 )
  30
  31 pkg_setup() {
  32         enewgroup vnstat
  33         enewuser vnstat -1 -1 /var/lib/vnstat vnstat
  34 }
  35
  36 src_prepare() {
  37         default
  38
  39         tc-export CC
  40
  41         sed -i \
  42                 -e 's|^\(MaxBWethnone.*\)$|#\1|' \
  43                 -e 's|^Daemon\(.*\) ""$|Daemon\1 "vnstat"|' \
  44                 -e 's|vnstat[.]log|vnstatd.log|' \
  45                 -e 's|vnstat[.]pid|vnstatd.pid|' \
  46                 -e 's|/var/run|/run|' \
  47                 cfg/${PN}.conf || die
  48         sed -i \
  49                 -e '/PIDFILE/s|/var/run|/run|' \
  50                 src/common.h || die
  51 }
  52
  53 src_compile() {
  54         emake ${PN} ${PN}d $(usex gd ${PN}i '')
  55 }
  56
  57 src_install() {
  58         use gd && dobin vnstati
  59         dobin vnstat vnstatd
  60
  61         exeinto /usr/share/${PN}
  62         newexe "${FILESDIR}"/vnstat.cron-r1 vnstat.cron
  63
  64         insinto /etc
  65         doins cfg/vnstat.conf
  66         fowners root:vnstat /etc/vnstat.conf
  67
  68         keepdir /var/lib/vnstat
  69         fowners vnstat:vnstat /var/lib/vnstat
  70
  71         newconfd "${FILESDIR}"/vnstatd.confd-r1 vnstatd
  72         newinitd "${FILESDIR}"/vnstatd.initd-r2 vnstatd
  73
  74         systemd_newunit "${FILESDIR}"/vnstatd.systemd vnstatd.service
  75         systemd_newtmpfilesd "${FILESDIR}"/vnstatd.tmpfile vnstatd.conf
  76
  77         use gd && doman man/vnstati.1
  78         doman man/vnstat.1 man/vnstatd.1
  79
  80         newdoc INSTALL README.setup
  81         dodoc CHANGES README UPGRADE FAQ examples/vnstat.cgi
  82 }