net-analyzer/vnstat/vnstat-1.13.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit toolchain-funcs user
   7
   8 DESCRIPTION="Console-based network traffic monitor that keeps statistics of network usage"
   9 HOMEPAGE="http://humdi.net/vnstat/"
  10 SRC_URI="http://humdi.net/vnstat/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 arm hppa ppc ppc64 sparc x86"
  15 IUSE="gd selinux test"
  16
  17 COMMON_DEPEND="
  18         gd? ( media-libs/gd[png] )
  19 "
  20 DEPEND="
  21         ${COMMON_DEPEND}
  22         test? ( dev-libs/check )
  23 "
  24 RDEPEND="
  25         ${COMMON_DEPEND}
  26         selinux? ( sec-policy/selinux-vnstatd )
  27 "
  28
  29 pkg_setup() {
  30         enewgroup vnstat
  31         enewuser vnstat -1 -1 /dev/null vnstat
  32 }
  33
  34 src_prepare() {
  35         tc-export CC
  36
  37         sed -i \
  38                 -e 's|vnstat[.]log|vnstatd.log|' \
  39                 -e 's|vnstat[.]pid|vnstatd/vnstatd.pid|' \
  40                 -e 's|/var/run|/run|' \
  41                 cfg/${PN}.conf || die
  42         sed -i \
  43                 -e '/PIDFILE/s|/var/run|/run|' \
  44                 src/common.h || die
  45 }
  46
  47 src_compile() {
  48         emake CFLAGS="${CFLAGS}" $(usex gd all '')
  49 }
  50
  51 src_install() {
  52         use gd && dobin src/vnstati
  53         dobin src/vnstat src/vnstatd
  54
  55         exeinto /etc/cron.hourly
  56         newexe "${FILESDIR}"/vnstat.cron vnstat
  57
  58         insinto /etc
  59         doins cfg/vnstat.conf
  60         fowners root:vnstat /etc/vnstat.conf
  61
  62         newconfd "${FILESDIR}"/vnstatd.confd vnstatd
  63         newinitd "${FILESDIR}"/vnstatd.initd-r1 vnstatd
  64
  65         use gd && doman man/vnstati.1
  66         doman man/vnstat.1 man/vnstatd.1
  67
  68         newdoc INSTALL README.setup
  69         dodoc CHANGES README UPGRADE FAQ examples/vnstat.cgi
  70 }