net-analyzer/sslsplit/sslsplit-0.5.5.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic
   7
   8 DESCRIPTION="Transparent SSL/TLS interception"
   9 HOMEPAGE="https://www.roe.ch/SSLsplit"
  10
  11 LICENSE="BSD-2"
  12 SLOT="0"
  13 IUSE="elibc_musl test"
  14 RESTRICT="!test? ( test )"
  15
  16 if [[ ${PV} == *9999 ]] ; then
  17         inherit git-r3
  18         EGIT_REPO_URI="https://github.com/droe/${PN}"
  19         EGIT_BRANCH="develop"
  20 else
  21         SRC_URI="https://github.com/droe/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  22         KEYWORDS="~amd64 ~x86"
  23 fi
  24
  25 RDEPEND="
  26         dev-libs/libevent[ssl,threads]
  27         dev-libs/openssl:0=
  28         net-libs/libnet:1.1
  29         elibc_musl? ( sys-libs/fts-standalone )"
  30 DEPEND="${RDEPEND}
  31         test? ( dev-libs/check )"
  32 BDEPEND=""
  33
  34 src_prepare() {
  35         default
  36
  37         use elibc_musl && append-libs "-lfts"
  38
  39         sed -i -e 's/-D_FORTIFY_SOURCE=2 //g' \
  40                 -e 's/\<FEATURES\>/SSLSPLIT_FEATURES/g' GNUmakefile || die
  41         sed -i '/opts_suite/d' main.t.c || die
  42 }
  43
  44 src_install() {
  45         emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" SYSCONFDIR="${EPREFIX}/etc" install
  46         dodoc AUTHORS.md NEWS.md README.md
  47 }