net-analyzer/neti/neti-2.0-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 DESCRIPTION="NETI@Home research project from GATech"
   7 HOMEPAGE="http://www.neti.gatech.edu"
   8 SRC_URI="mirror://sourceforge/neti/${P}.tar.gz"
   9
  10 KEYWORDS="~ppc x86"
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 IUSE="zlib java"
  14
  15 DEPEND="
  16         java? ( || ( >=virtual/jdk-1.2 >=virtual/jre-1.2 ) )
  17         net-libs/libpcap
  18 "
  19 RDEPEND="${DEPEND}"
  20
  21 RESTRICT="test"
  22
  23 src_configure() {
  24         econf $(use_with zlib)
  25 }
  26
  27 src_compile() {
  28         emake NETILogParse neti
  29
  30         use java && emake javadir=/usr/share/${PN} classjava.stamp
  31 }
  32
  33 src_install() {
  34         emake \
  35                 DESTDIR="${D}" \
  36                 install-sbinPROGRAMS \
  37                 install-sysconfDATA \
  38                 install-man \
  39                 install-info
  40
  41         if use java; then
  42                 emake \
  43                         DESTDIR="${D}" \
  44                         javadir=/usr/share/${PN} \
  45                         install-javaJAVA \
  46                         install-javaDATA
  47
  48                 echo cd /usr/share/${PN}\;java -cp /usr/share/${PN} NETIMap > "${WORKDIR}"/NETIMap
  49                 dobin "${WORKDIR}"/NETIMap
  50         fi
  51
  52         dodoc README AUTHORS
  53         newinitd "${FILESDIR}"/neti-init2 neti
  54 }