net-analyzer/linkchecker/linkchecker-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 PYTHON_REQ_USE="sqlite?"
   8
   9 EGIT_REPO_URI="https://github.com/linkcheck/linkchecker.git"
  10 inherit bash-completion-r1 distutils-r1 eutils git-r3
  11
  12 DESCRIPTION="Check websites for broken links"
  13 HOMEPAGE="https://github.com/linkcheck/linkchecker"
  14 SRC_URI=""
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS=""
  19 IUSE="sqlite"
  20
  21 RDEPEND="
  22         dev-python/dnspython[${PYTHON_USEDEP}]
  23         dev-python/pyxdg[${PYTHON_USEDEP}]
  24         >=dev-python/requests-2.4[${PYTHON_USEDEP}]
  25 "
  26 DEPEND=""
  27
  28 RESTRICT="test"
  29
  30 python_prepare_all() {
  31         local PATCHES=(
  32                 "${FILESDIR}/${PN}-9.3-bash-completion.patch"
  33         )
  34
  35         distutils-r1_python_prepare_all
  36 }
  37
  38 python_install_all() {
  39         DOCS=(
  40                 doc/changelog.txt
  41                 doc/development.mdwn
  42                 doc/python3.txt
  43                 doc/upgrading.txt
  44         )
  45         distutils-r1_python_install_all
  46
  47         rm "${ED}"/usr/share/applications/linkchecker.desktop || die
  48
  49         newbashcomp config/linkchecker-completion ${PN}
  50 }
  51
  52 pkg_postinst() {
  53         optfeature "bash-completion support" dev-python/argcomplete[${PYTHON_USEDEP}]
  54         optfeature "Virus scanning" app-antivirus/clamav
  55         optfeature "Geo IP support" dev-python/geoip-python[${PYTHON_USEDEP}]
  56 }