net-analyzer/gvmd/gvmd-8.0.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 CMAKE_MAKEFILE_GENERATOR="emake"
   7 inherit cmake flag-o-matic systemd toolchain-funcs
   8
   9 DESCRIPTION="Greenbone vulnerability manager, previously named openvas-manager"
  10 HOMEPAGE="https://www.greenbone.net/en/"
  11 SRC_URI="https://github.com/greenbone/gvmd/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 SLOT="0"
  14 LICENSE="GPL-2+"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="extras postgres sqlite"
  17 REQUIRED_USE="|| ( postgres sqlite )"
  18
  19 DEPEND="
  20         dev-libs/libgcrypt:0=
  21         dev-libs/libical
  22         >=net-analyzer/gvm-libs-10.0.1
  23         net-libs/gnutls:=[tools]
  24         extras?   ( app-text/xmlstarlet
  25                     dev-texlive/texlive-latexextra )
  26         postgres? ( dev-db/postgresql:* )
  27         sqlite?   ( dev-db/sqlite:3 )"
  28
  29 RDEPEND="
  30         ${DEPEND}
  31         ~net-analyzer/openvas-scanner-6.0.1"
  32
  33 BDEPEND="
  34         sys-devel/bison
  35         sys-devel/flex
  36         virtual/pkgconfig
  37         extras? ( app-doc/doxygen[dot]
  38                   app-doc/xmltoman
  39                   app-text/htmldoc
  40                   dev-libs/libxslt
  41         )"
  42
  43 PATCHES=(
  44         # Install exec. to /usr/bin instead of /usr/sbin
  45         "${FILESDIR}/${P}-sbin.patch"
  46         # Fix permissions for user gvm.
  47         "${FILESDIR}/${P}-tmplock.patch"
  48 )
  49
  50 src_prepare() {
  51         cmake_src_prepare
  52         # QA-Fix | Use correct FHS/Gentoo policy paths for 8.0.1
  53         sed -i -e "s*share/doc/gvm/html/*share/doc/gvmd-${PV}/html/*g" "$S"/doc/CMakeLists.txt || die
  54         sed -i -e "s*/doc/gvm/*/doc/gvmd-${PV}/*g" "$S"/CMakeLists.txt || die
  55         # QA-Fix | Remove !CLANG Doxygen warnings for 8.0.1
  56         if use extras; then
  57                 if ! tc-is-clang; then
  58                    local f
  59                    for f in doc/*.in
  60                    do
  61                         sed -i \
  62                                 -e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
  63                                 -e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
  64                                 "${f}" || die "couldn't disable CLANG parsing"
  65                    done
  66                 fi
  67         fi
  68 }
  69
  70 src_configure() {
  71         local mycmakeargs=(
  72                 "-DLOCALSTATEDIR=${EPREFIX}/var"
  73                 "-DSYSCONFDIR=${EPREFIX}/etc"
  74         )
  75         # Add release hardening flags for 8.0.1
  76         append-cflags -Wno-nonnull -Wformat -Wformat-security -D_FORTIFY_SOURCE=2 -fstack-protector
  77         append-ldflags -Wl,-z,relro -Wl,-z,now
  78         cmake_src_configure
  79 }
  80
  81 src_compile() {
  82         cmake_src_compile
  83         if use extras; then
  84                 cmake_build -C "${BUILD_DIR}" doc
  85                 cmake_build doc-full -C "${BUILD_DIR}" doc
  86                 HTML_DOCS=( "${BUILD_DIR}"/doc/generated/html/. )
  87         fi
  88         cmake_build rebuild_cache
  89 }
  90
  91 src_install() {
  92         cmake_src_install
  93
  94         dodir /etc/gvm
  95         insinto /etc/gvm
  96         doins -r "${FILESDIR}"/*sync*
  97
  98         dodir /etc/gvm/sysconfig
  99         insinto /etc/gvm/sysconfig
 100         doins "${FILESDIR}/${PN}-daemon.conf"
 101
 102         exeinto /etc/gvm
 103         doexe "${FILESDIR}"/gvmd-startpre.sh
 104
 105         fowners -R gvm:gvm /etc/gvm
 106
 107         newinitd "${FILESDIR}/${PN}.init" "${PN}"
 108         newconfd "${FILESDIR}/${PN}-daemon.conf" "${PN}"
 109
 110         insinto /etc/logrotate.d
 111         newins "${FILESDIR}/${PN}.logrotate" "${PN}"
 112
 113         systemd_dounit "${FILESDIR}/${PN}.service"
 114
 115         # Set proper permissions on required files/directories
 116         keepdir /var/lib/gvm/gvmd
 117         fowners -R gvm:gvm /var/lib/gvm
 118 }