net-analyzer/bwm-ng/bwm-ng-0.6.1-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Bandwidth Monitor NG is a small and simple console-based bandwidth monitor"
   9 SRC_URI="http://www.gropp.org/bwm-ng/${P}.tar.gz"
  10 HOMEPAGE="http://www.gropp.org/"
  11
  12 KEYWORDS="amd64 ~arm ppc x86"
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 IUSE="csv html"
  16
  17 RDEPEND="sys-libs/ncurses:0=
  18         >=sys-apps/net-tools-1.60-r1"
  19 DEPEND="${RDEPEND}"
  20
  21 PATCHES=(
  22         "${FILESDIR}"/${P}-fix-buildsystem.patch
  23         "${FILESDIR}"/${P}-static-inline.patch
  24 )
  25
  26 src_prepare() {
  27         default
  28         mv configure.{in,ac} || die
  29         eautoreconf
  30 }
  31
  32 src_configure() {
  33         econf \
  34                 $(use_enable csv) \
  35                 $(use_enable html) \
  36                 --enable-ncurses \
  37                 --with-procnetdev
  38 }