media-video/xine-ui/xine-ui-0.99.10.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools gnome2-utils xdg-utils
   7
   8 DESCRIPTION="Xine movie player"
   9 HOMEPAGE="https://xine-project.org/home"
  10 SRC_URI="mirror://sourceforge/xine/${P}.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~hppa ppc ppc64 x86"
  15 IUSE="aalib curl debug libcaca lirc nls readline vdr X xinerama"
  16
  17 RDEPEND="
  18         || ( app-arch/tar app-arch/libarchive )
  19         media-libs/libpng:0=
  20         >=media-libs/xine-lib-1.2:=[aalib?,libcaca?]
  21         virtual/jpeg:0
  22         aalib? ( media-libs/aalib:= )
  23         curl? ( >=net-misc/curl-7.10.2:= )
  24         libcaca? ( media-libs/libcaca:= )
  25         lirc? ( app-misc/lirc:= )
  26         nls? ( virtual/libintl )
  27         readline? ( >=sys-libs/readline-6.2:= )
  28         X? (
  29                 x11-libs/libICE:=
  30                 x11-libs/libSM:=
  31                 x11-libs/libX11:=
  32                 x11-libs/libXext:=
  33                 x11-libs/libXft:=
  34                 x11-libs/libXrender:=
  35                 x11-libs/libXScrnSaver:=
  36                 x11-libs/libXtst:=
  37                 x11-libs/libXv:=
  38                 x11-libs/libXxf86vm:=
  39                 xinerama? ( x11-libs/libXinerama:= )
  40         )
  41 "
  42 DEPEND="${RDEPEND}
  43         virtual/pkgconfig
  44         nls? ( >=sys-devel/gettext-0.18.3 )
  45         X? (
  46                 x11-base/xorg-proto
  47                 x11-libs/libXt
  48         )
  49 "
  50
  51 PATCHES=(
  52         "${FILESDIR}"/${P}-desktop.patch
  53         "${FILESDIR}"/${P}-libcaca.patch
  54 )
  55
  56 src_prepare() {
  57         default
  58         eautoreconf
  59         rm misc/xine-bugreport || die
  60 }
  61
  62 src_configure() {
  63         econf \
  64                 $(use_enable nls) \
  65                 $(use_enable xinerama) \
  66                 $(use_enable lirc) \
  67                 $(use_enable vdr vdr-keys) \
  68                 --disable-nvtvsimple \
  69                 $(use_enable debug) \
  70                 $(use_with X x) \
  71                 $(use_with readline) \
  72                 $(use_with curl) \
  73                 $(use_with aalib) \
  74                 $(use_with libcaca caca) \
  75                 --without-fb
  76 }
  77
  78 src_install() {
  79         # xine-list apparently may cause sandbox violation, bug 654394
  80         addpredict /dev/dri
  81
  82         emake \
  83                 DESTDIR="${D}" \
  84                 docdir="/usr/share/doc/${PF}" \
  85                 docsdir="/usr/share/doc/${PF}" \
  86                 install
  87
  88         einstalldocs
  89 }
  90
  91 pkg_postinst() {
  92         xdg_desktop_database_update
  93         xdg_mimeinfo_database_update
  94         gnome2_icon_cache_update
  95 }
  96
  97 pkg_postrm() {
  98         xdg_desktop_database_update
  99         xdg_mimeinfo_database_update
 100         gnome2_icon_cache_update
 101 }