media-video/smplayer/smplayer-17.10.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PLOCALES="am ar_SY ar bg ca cs da de el en_GB en en_US es et eu fa fi fr gl
   7 he_IL hr hu id it ja ka ko ku lt mk ms_MY nl nn_NO pl pt_BR pt ro_RO ru_RU
   8 sk sl_SI sq_AL sr sv th tr uk_UA uz vi_VN zh_CN zh_TW"
   9 PLOCALE_BACKUP="en_US"
  10
  11 inherit l10n qmake-utils
  12
  13 DESCRIPTION="Great Qt GUI front-end for mplayer/mpv"
  14 HOMEPAGE="http://www.smplayer.eu/"
  15 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  16
  17 LICENSE="GPL-2+ BSD-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux"
  20 IUSE="autoshutdown bidi debug mpris"
  21
  22 COMMON_DEPEND="
  23         dev-qt/qtcore:5
  24         dev-qt/qtgui:5
  25         dev-qt/qtnetwork:5[ssl]
  26         dev-qt/qtscript:5
  27         dev-qt/qtsingleapplication[X,qt5]
  28         dev-qt/qtwidgets:5
  29         dev-qt/qtxml:5
  30         sys-libs/zlib
  31         autoshutdown? ( dev-qt/qtdbus:5 )
  32         mpris? ( dev-qt/qtdbus:5 )
  33 "
  34 DEPEND="${COMMON_DEPEND}
  35         dev-qt/linguist-tools:5
  36 "
  37 RDEPEND="${COMMON_DEPEND}
  38         || (
  39                 media-video/mplayer[bidi?,libass,png,X]
  40                 (
  41                         >=media-video/mpv-0.15.0[libass,X]
  42                         >=net-misc/youtube-dl-2014.11.26
  43                 )
  44         )
  45 "
  46
  47 PATCHES=(
  48         "${FILESDIR}/${PN}-14.9.0.6966-unbundle-qtsingleapplication.patch" # bug 487544
  49         "${FILESDIR}/${PN}-17.1.0-advertisement_crap.patch"
  50 )
  51
  52 src_prepare() {
  53         use bidi || PATCHES+=( "${FILESDIR}"/${PN}-16.4.0-zero-bidi.patch )
  54
  55         default
  56
  57         # Upstream Makefile sucks
  58         sed -i -e "/^PREFIX=/ s:/usr/local:${EPREFIX}/usr:" \
  59                 -e "/^DOC_PATH=/ s:packages/smplayer:${PF}:" \
  60                 -e '/\.\/get_svn_revision\.sh/,+2c\
  61         cd src && $(DEFS) $(MAKE)' \
  62                 Makefile || die
  63
  64         # Turn off online update checker, bug #479902
  65         sed -e 's:DEFINES += UPDATE_CHECKER:#&:' \
  66                 -e 's:DEFINES += CHECK_UPGRADED:#&:' \
  67                 -i src/smplayer.pro || die
  68
  69         # Turn off intrusive share widget
  70         sed -e 's:DEFINES += SHARE_WIDGET:#&:' \
  71                 -i src/smplayer.pro || die
  72
  73         # Toggle autoshutdown option which pulls in dbus, bug #524392
  74         if ! use autoshutdown ; then
  75                 sed -e 's:DEFINES += AUTO_SHUTDOWN_PC:#&:' \
  76                         -i src/smplayer.pro || die
  77         fi
  78
  79         # Turn debug message flooding off
  80         if ! use debug ; then
  81                 sed -e 's:#\(DEFINES += NO_DEBUG_ON_CONSOLE\):\1:' \
  82                         -i src/smplayer.pro || die
  83         fi
  84
  85         # MPRIS2 pulls in dbus, bug #553710
  86         if ! use mpris ; then
  87                 sed -e 's:DEFINES += MPRIS2:#&:' \
  88                         -i src/smplayer.pro || die
  89         fi
  90
  91         # Commented out because it gives false positives
  92         #l10n_find_plocales_changes "${S}"/src/translations ${PN}_ .ts
  93 }
  94
  95 src_configure() {
  96         cd src || die
  97         eqmake5
  98 }
  99
 100 gen_translation() {
 101         local mydir="$(qt5_get_bindir)"
 102
 103         ebegin "Generating $1 translation"
 104         "${mydir}"/lrelease ${PN}_${1}.ts
 105         eend $? || die "failed to generate $1 translation"
 106 }
 107
 108 src_compile() {
 109         default
 110
 111         cd src/translations || die
 112         l10n_for_each_locale_do gen_translation
 113 }
 114
 115 src_install() {
 116         # remove unneeded copies of the GPL
 117         rm -f Copying* docs/*/gpl.html || die
 118         # don't install empty dirs
 119         rmdir --ignore-fail-on-non-empty docs/* || die
 120
 121         default
 122 }