media-video/raspberrypi-omxplayer/raspberrypi-omxplayer-0_p20160528.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils toolchain-funcs flag-o-matic
   7
   8 GIT_COMMIT="791d7df"
   9 DESCRIPTION="Command line media player for the Raspberry Pi"
  10 HOMEPAGE="https://github.com/popcornmix/omxplayer"
  11 SRC_URI="https://github.com/popcornmix/omxplayer/tarball/${GIT_COMMIT} -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~arm"
  16 IUSE="X"
  17
  18 RDEPEND="dev-libs/libpcre
  19         media-fonts/freefont
  20         || ( media-libs/raspberrypi-userland media-libs/raspberrypi-userland-bin )
  21         sys-apps/dbus
  22         sys-apps/fbset
  23         virtual/ffmpeg
  24         dev-libs/boost
  25         media-libs/freetype:2
  26         X? (
  27                 x11-apps/xrefresh
  28                 x11-apps/xset
  29         )"
  30 DEPEND="${RDEPEND}
  31         virtual/pkgconfig"
  32
  33 S="${WORKDIR}/popcornmix-omxplayer-${GIT_COMMIT}"
  34
  35 src_prepare() {
  36         epatch "${FILESDIR}"/Makefile-0_p20160528.patch \
  37                 "${FILESDIR}"/fonts-path.patch
  38
  39         cat > Makefile.include << EOF
  40 LIBS=-lvchostif -lvchiq_arm -lvcos -lbcm_host -lEGL -lGLESv2 -lopenmaxil -lrt -lpthread
  41 EOF
  42
  43         tc-export CXX
  44 }
  45
  46 src_compile() {
  47         emake omxplayer.bin
  48 }
  49
  50 src_install() {
  51         dobin omxplayer omxplayer.bin
  52         dodoc README.md
  53 }