media-video/qmplay2/qmplay2-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake xdg-utils
   7
   8 DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
   9 HOMEPAGE="https://github.com/zaps166/QMPlay2"
  10
  11 if [[ ${PV} == *9999 ]]; then
  12         inherit git-r3
  13         EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
  14 else
  15         SRC_URI="https://github.com/zaps166/QMPlay2/archive/${PV}.tar.gz -> ${P}.tar.gz"
  16         KEYWORDS="~amd64 ~x86"
  17         S="${WORKDIR}/QMPlay2-${PV}"
  18 fi
  19
  20 LICENSE="LGPL-3"
  21 SLOT="0"
  22
  23 IUSE="avdevice +audiofilters avresample +alsa cdio cuvid dbus +extensions
  24         +ffmpeg gme inputs +lastfm libass lyrics mediabrowser modplug mpris2
  25         notifications opengl portaudio pulseaudio sid svg taglib vaapi vdpau
  26         +videofilters visualizations xv"
  27
  28 REQUIRED_USE="
  29         audiofilters? ( || ( alsa portaudio pulseaudio ) )
  30         avdevice? ( ffmpeg )
  31         avresample? ( ffmpeg )
  32         lastfm? ( extensions )
  33         lyrics? ( extensions )
  34         mediabrowser? ( extensions )
  35         mpris2? ( extensions dbus )
  36         vaapi? ( ffmpeg opengl )
  37         vdpau? ( ffmpeg )"
  38
  39 RDEPEND="
  40         alsa? ( media-libs/alsa-lib )
  41         cdio? ( dev-libs/libcdio[cddb] )
  42         dev-qt/qtcore:5
  43         || (
  44                 dev-qt/qtgui:5[X(-)]
  45                 dev-qt/qtgui:5[xcb(-)]
  46         )
  47         dev-qt/qtwidgets:5
  48         dev-qt/qtx11extras:5
  49         dbus? ( dev-qt/qtdbus:5 )
  50         ffmpeg? ( media-video/ffmpeg )
  51         gme? ( media-libs/game-music-emu )
  52         libass? ( media-libs/libass )
  53         mediabrowser? ( dev-qt/qtdeclarative:5 )
  54         opengl? ( virtual/opengl )
  55         portaudio? ( media-libs/portaudio )
  56         pulseaudio? ( media-sound/pulseaudio )
  57         sid? ( media-libs/libsidplayfp )
  58         svg? ( dev-qt/qtsvg:5 )
  59         taglib? ( media-libs/taglib )
  60         vaapi? (
  61                 >=media-video/ffmpeg-4.1.0[vaapi]
  62                 x11-libs/libva[drm,opengl] )
  63         vdpau? ( media-video/ffmpeg[vdpau] )
  64         xv? ( x11-libs/libXv )"
  65
  66 DEPEND="${RDEPEND}"
  67 BDEPEND="
  68         dev-qt/linguist-tools:5
  69         virtual/pkgconfig"
  70
  71 src_prepare() {
  72         # disable compress man pages
  73         sed -r \
  74                 -e 's/if\(GZIP\)/if\(TRUE\)/' \
  75                 -e 's/(install.+QMPlay2\.1)\.gz/\1/' \
  76                 -i src/gui/CMakeLists.txt || die
  77
  78         cmake_src_prepare
  79 }
  80
  81 src_configure() {
  82         local mycmakeargs=(
  83                 # core
  84                 -DUSE_ALSA=$(usex alsa)
  85                 -DUSE_AUDIOCD=$(usex cdio)
  86                 -DUSE_AVRESAMPLE=$(usex avresample)
  87                 -DUSE_FREEDESKTOP_NOTIFICATIONS=$(usex dbus) # https://github.com/zaps166/QMPlay2/issues/134
  88                 -DUSE_LIBASS=$(usex libass)
  89                 -DUSE_NOTIFY=$(usex notifications)
  90                 -DUSE_OPENGL2=$(usex opengl)
  91                 -DUSE_XVIDEO=$(usex xv)
  92
  93                 # ffmpeg
  94                 -DUSE_FFMPEG=$(usex ffmpeg)
  95                 -DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
  96                 -DUSE_FFMPEG_VAAPI=$(usex vaapi)
  97                 -DUSE_FFMPEG_VDPAU=$(usex vdpau)
  98
  99                 # modules
 100                 -DUSE_AUDIOFILTERS=$(usex audiofilters)
 101                 -DUSE_CUVID=$(usex cuvid)
 102                 -DUSE_EXTENSIONS=$(usex extensions)
 103                 -DUSE_INPUTS=$(usex inputs)
 104                 -DUSE_MODPLUG=$(usex modplug)
 105                 -DUSE_PORTAUDIO=$(usex portaudio)
 106                 -DUSE_PULSEAUDIO=$(usex pulseaudio)
 107                 -DUSE_VIDEOFILTERS=$(usex videofilters)
 108                 -DUSE_VISUALIZATIONS=$(usex visualizations)
 109
 110                 # gui
 111                 -DUSE_TAGLIB=$(usex taglib)
 112
 113                 # chiptune
 114                 -DUSE_CHIPTUNE_GME=$(usex gme)
 115                 -DUSE_CHIPTUNE_SID=$(usex sid)
 116
 117                 # extensions
 118                 -DUSE_LASTFM=$(usex lastfm)
 119                 -DUSE_LYRICS=$(usex lyrics)
 120                 -DUSE_MEDIABROWSER=$(usex mediabrowser)
 121                 -DUSE_MPRIS2=$(usex mpris2)
 122         )
 123
 124         if [[ ${PV} == *9999 ]]; then
 125                 mycmakeargs+=( USE_GIT_VERSION=ON )
 126         else
 127                 mycmakeargs+=( USE_GIT_VERSION=OFF )
 128         fi
 129
 130         cmake_src_configure
 131 }
 132
 133 pkg_postinst() {
 134         xdg_icon_cache_update
 135         xdg_mimeinfo_database_update
 136         xdg_desktop_database_update
 137 }
 138
 139 pkg_postrm() {
 140         xdg_icon_cache_update
 141         xdg_mimeinfo_database_update
 142         xdg_desktop_database_update
 143 }