media-video/photofilmstrip/photofilmstrip-2.1.0-r2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5 PYTHON_COMPAT=( python2_7 )
   6 PYTHON_REQ_USE="sqlite"
   7 DISTUTILS_SINGLE_IMPL=1
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Movie slideshow creator using Ken Burns effect"
  12 HOMEPAGE="http://www.photofilmstrip.org"
  13 SRC_URI="mirror://sourceforge/photostoryx/${PN}/${PV}/${P}.tar.gz"
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="cairo sdl"
  19
  20 RDEPEND="
  21         dev-python/wxpython:3.0[cairo?,${PYTHON_USEDEP}]
  22         dev-python/pillow[${PYTHON_USEDEP}]
  23         media-video/mplayer[encode]
  24         sdl? ( dev-python/pygame[${PYTHON_USEDEP}] )
  25 "
  26 DEPEND="${RDEPEND}"
  27
  28 # Fix bug #472774 (https://bugs.gentoo.org/show_bug.cgi?id=472774)
  29 PATCHES=(
  30         "${FILESDIR}/${P}-PIL_modules_imports_fix.patch"
  31         "${FILESDIR}/${P}-PIL_tostring_fix.patch"
  32 )
  33
  34 DOCS=( CHANGES COPYING README )
  35
  36 src_prepare() {
  37         # Remove unneeded icon resources update needing running X
  38         # Fix app doc/help files paths
  39         sed -i \
  40                 -e '/self\._make_resources\(\)/d' \
  41                 -e "s:\(os\.path\.join(\"share\", \"doc\", \"\)photofilmstrip:\1${PF}:" \
  42                 setup.py || die
  43
  44         sed -i \
  45                  -e "s:\"photofilmstrip\":\"${PF}\":" \
  46                  photofilmstrip/gui/HelpViewer.py || die
  47
  48         # Fix desktop file entry
  49         sed -i \
  50                 -e '/^Version.*/d' \
  51                 data/photofilmstrip.desktop || die
  52
  53         distutils-r1_src_prepare
  54 }
  55
  56 src_install() {
  57         doman docs/manpage/*
  58
  59         # Do not compress the apps help files
  60         docompress -x /usr/share/doc/${PF}/${PN}.hh{c,k,p}
  61
  62         distutils-r1_src_install
  63 }