media-video/orion/orion-1.6.6.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit desktop qmake-utils xdg
   6
   7 DESCRIPTION="Cross-platform Twitch client"
   8 HOMEPAGE="https://alamminsalo.github.io/orion/"
   9 SRC_URI="https://github.com/alamminsalo/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="+mpv qtav qtmedia"
  15
  16 DEPEND=">=dev-qt/qtquickcontrols-5.8:5
  17         >=dev-qt/qtquickcontrols2-5.8:5
  18         >=dev-qt/qtsvg-5.8:5
  19         >=dev-qt/qtwebengine-5.8:5
  20         mpv? ( media-video/mpv[libmpv] )
  21         qtav? ( media-libs/qtav )
  22         qtmedia? ( >=dev-qt/qtmultimedia-5.8:5 )"
  23 RDEPEND="${DEPEND}
  24         !mpv? ( media-plugins/gst-plugins-hls )"
  25
  26 REQUIRED_USE="^^ ( mpv qtav qtmedia )"
  27
  28 PATCHES=(
  29         "${FILESDIR}"/${P}-fix_login.patch
  30         "${FILESDIR}"/${P}-mpv_compilation.patch
  31         "${FILESDIR}"/${P}-mpv_backwards.patch
  32 )
  33
  34 src_configure() {
  35         local PLAYER
  36         if use mpv; then
  37                 PLAYER=mpv
  38         elif use qtav; then
  39                 PLAYER=qtav
  40         else
  41                 PLAYER=multimedia
  42         fi
  43         eqmake5 ${PN}.pro CONFIG+=${PLAYER}
  44 }
  45
  46 src_install() {
  47         dobin ${PN}
  48         domenu distfiles/*.desktop
  49
  50         insinto /usr/share/icons/hicolor/scalable/apps
  51         doins distfiles/${PN}.svg
  52 }