media-video/mplayer/mplayer-1.2_pre20150214-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
   8 ESVN_REPO_URI="svn://svn.mplayerhq.hu/mplayer/trunk"
   9 [[ ${PV} = *9999* ]] && SVN_ECLASS="subversion git-2" || SVN_ECLASS=""
  10
  11 inherit toolchain-funcs eutils flag-o-matic multilib base ${SVN_ECLASS}
  12
  13 IUSE="cpu_flags_x86_3dnow cpu_flags_x86_3dnowext a52 aalib +alsa altivec aqua bidi bl bluray
  14 bs2b cddb +cdio cdparanoia cpudetection debug dga
  15 directfb doc dts dv dvb +dvd +dvdnav +enca +encode faac faad fbcon
  16 ftp gif ggi gsm +iconv ipv6 jack joystick jpeg jpeg2k kernel_linux ladspa
  17 +libass libcaca libmpeg2 lirc live lzo mad md5sum +cpu_flags_x86_mmx cpu_flags_x86_mmxext mng mp3 nas
  18 +network nut openal opengl +osdmenu oss png pnm pulseaudio pvr
  19 radio rar rtc rtmp samba selinux +shm sdl speex cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_ssse3
  20 tga theora tremor +truetype toolame twolame +unicode v4l vdpau vidix
  21 vorbis +X x264 xanim xinerama +xscreensaver +xv xvid xvmc zoran"
  22
  23 VIDEO_CARDS="s3virge mga tdfx"
  24 for x in ${VIDEO_CARDS}; do
  25         IUSE+=" video_cards_${x}"
  26 done
  27
  28 FONT_URI="
  29         mirror://mplayer/releases/fonts/font-arial-iso-8859-1.tar.bz2
  30         mirror://mplayer/releases/fonts/font-arial-iso-8859-2.tar.bz2
  31         mirror://mplayer/releases/fonts/font-arial-cp1250.tar.bz2
  32 "
  33 if [[ ${PV} == *9999* ]]; then
  34         RELEASE_URI=""
  35 elif [ "${PV%_rc*}" = "${PV}" -a "${PV%_pre*}" = "${PV}" ]; then
  36         MY_P="MPlayer-${PV}"
  37         S="${WORKDIR}/${MY_P}"
  38         RELEASE_URI="mirror://mplayer/releases/${MY_P}.tar.xz"
  39 else
  40         RELEASE_URI="mirror://gentoo/${P}.tar.xz"
  41 fi
  42 SRC_URI="${RELEASE_URI}
  43         !truetype? ( ${FONT_URI} )"
  44
  45 DESCRIPTION="Media Player for Linux"
  46 HOMEPAGE="http://www.mplayerhq.hu/"
  47
  48 FONT_RDEPS="
  49         virtual/ttf-fonts
  50         media-libs/fontconfig
  51         >=media-libs/freetype-2.2.1:2
  52 "
  53 X_RDEPS="
  54         x11-libs/libXext
  55         x11-libs/libXxf86vm
  56 "
  57 # Rar: althrought -gpl version is nice, it cant do most functions normal rars can
  58 #       nemesi? ( net-libs/libnemesi )
  59 RDEPEND+="
  60         sys-libs/ncurses:0=
  61         app-arch/bzip2
  62         sys-libs/zlib
  63         >=media-video/ffmpeg-2.0:0=[vdpau?]
  64         a52? ( media-libs/a52dec )
  65         aalib? ( media-libs/aalib )
  66         alsa? ( media-libs/alsa-lib )
  67         bidi? ( dev-libs/fribidi )
  68         bluray? ( >=media-libs/libbluray-0.2.1 )
  69         bs2b? ( media-libs/libbs2b )
  70         cdio? ( dev-libs/libcdio )
  71         cdparanoia? ( !cdio? ( media-sound/cdparanoia ) )
  72         dga? ( x11-libs/libXxf86dga )
  73         directfb? ( dev-libs/DirectFB )
  74         dts? ( media-libs/libdca )
  75         dv? ( media-libs/libdv )
  76         dvb? ( virtual/linuxtv-dvb-headers )
  77         dvd? ( >=media-libs/libdvdread-4.1.3 )
  78         dvdnav? ( >=media-libs/libdvdnav-4.1.3 )
  79         encode? (
  80                 !twolame? ( toolame? ( media-sound/toolame ) )
  81                 twolame? ( media-sound/twolame )
  82                 faac? ( media-libs/faac )
  83                 mp3? ( media-sound/lame )
  84                 x264? ( >=media-libs/x264-0.0.20100423:= )
  85                 xvid? ( media-libs/xvid )
  86         )
  87         enca? ( app-i18n/enca )
  88         faad? ( media-libs/faad2 )
  89         ggi? ( media-libs/libggi media-libs/libggiwmh )
  90         gif? ( media-libs/giflib )
  91         gsm? ( media-sound/gsm )
  92         iconv? ( virtual/libiconv )
  93         jack? ( media-sound/jack-audio-connection-kit )
  94         jpeg? ( virtual/jpeg:0 )
  95         jpeg2k? ( media-libs/openjpeg:0 )
  96         ladspa? ( media-libs/ladspa-sdk )
  97         libass? ( >=media-libs/libass-0.9.10:=[enca?] )
  98         libcaca? ( media-libs/libcaca )
  99         libmpeg2? ( media-libs/libmpeg2 )
 100         lirc? ( app-misc/lirc )
 101         live? ( media-plugins/live )
 102         lzo? ( >=dev-libs/lzo-2 )
 103         mad? ( media-libs/libmad )
 104         mng? ( media-libs/libmng:= )
 105         mp3? ( media-sound/mpg123 )
 106         nas? ( media-libs/nas )
 107         nut? ( >=media-libs/libnut-661 )
 108         openal? ( media-libs/openal )
 109         opengl? ( virtual/opengl )
 110         png? ( media-libs/libpng:0= )
 111         pnm? ( media-libs/netpbm )
 112         pulseaudio? ( media-sound/pulseaudio )
 113         rar? (
 114                 || (
 115                         app-arch/unrar
 116                         app-arch/rar
 117                 )
 118         )
 119         rtmp? ( media-video/rtmpdump )
 120         samba? ( net-fs/samba )
 121         sdl? ( media-libs/libsdl )
 122         speex? ( media-libs/speex )
 123         theora? ( media-libs/libtheora[encode?] )
 124         tremor? ( media-libs/tremor )
 125         truetype? ( ${FONT_RDEPS} )
 126         vdpau? ( x11-libs/libvdpau )
 127         vorbis? ( !tremor? ( media-libs/libvorbis ) )
 128         X? ( ${X_RDEPS} )
 129         xanim? ( media-video/xanim )
 130         xinerama? ( x11-libs/libXinerama )
 131         xscreensaver? ( x11-libs/libXScrnSaver )
 132         xv? ( x11-libs/libXv )
 133         xvmc? ( x11-libs/libXvMC )
 134 "
 135
 136 X_DEPS="
 137         x11-proto/videoproto
 138         x11-proto/xf86vidmodeproto
 139 "
 140 ASM_DEP="dev-lang/yasm"
 141 DEPEND="${RDEPEND}
 142         virtual/pkgconfig
 143         dga? ( x11-proto/xf86dgaproto )
 144         X? ( ${X_DEPS} )
 145         xinerama? ( x11-proto/xineramaproto )
 146         xscreensaver? ( x11-proto/scrnsaverproto )
 147         amd64? ( ${ASM_DEP} )
 148         doc? (
 149                 dev-libs/libxslt app-text/docbook-xml-dtd
 150                 app-text/docbook-xsl-stylesheets
 151         )
 152         x86? ( ${ASM_DEP} )
 153         x86-fbsd? ( ${ASM_DEP} )
 154 "
 155 RDEPEND+="
 156         selinux? ( sec-policy/selinux-mplayer )
 157 "
 158
 159 SLOT="0"
 160 LICENSE="GPL-2"
 161 if [[ ${PV} != *9999* ]]; then
 162         KEYWORDS="alpha amd64 arm hppa ppc ppc64 sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
 163 else
 164         KEYWORDS="alpha amd64 arm hppa ppc ppc64 sparc"
 165 fi
 166
 167 # faac codecs are nonfree
 168 # libcdio support: prefer libcdio over cdparanoia and don't check for cddb w/cdio
 169 # dvd navigation requires dvd read support
 170 # ass and freetype font require iconv and ass requires freetype fonts
 171 # unicode transformations are usefull only with iconv
 172 # radio requires oss or alsa backend
 173 # xvmc requires xvideo support
 174 REQUIRED_USE="
 175         dga? ( X )
 176         dvdnav? ( dvd )
 177         enca? ( iconv )
 178         ggi? ( X )
 179         libass? ( truetype )
 180         opengl? ( X )
 181         osdmenu? ( X )
 182         truetype? ( iconv )
 183         vdpau? ( X )
 184         vidix? ( X )
 185         xinerama? ( X )
 186         xscreensaver? ( X )
 187         xv? ( X )
 188         xvmc? ( xv )"
 189 RESTRICT="faac? ( bindist )"
 190
 191 PATCHES=(
 192         # Work with pulseaudio-6, bug #549680, https://trac.mplayerhq.hu/ticket/2241
 193         "${FILESDIR}"/${PN}-1.2_pre20150214-pulseaudio-6.0.patch
 194 )
 195
 196 pkg_setup() {
 197         if [[ ${PV} == *9999* ]]; then
 198                 elog
 199                 elog "This is a live ebuild which installs the latest from upstream's"
 200                 elog "subversion repository, and is unsupported by Gentoo."
 201                 elog "Everything but bugs in the ebuild itself will be ignored."
 202                 elog
 203         fi
 204
 205         if use cpudetection; then
 206                 ewarn
 207                 ewarn "You've enabled the cpudetection flag. This feature is"
 208                 ewarn "included mainly for people who want to use the same"
 209                 ewarn "binary on another system with a different CPU architecture."
 210                 ewarn "MPlayer will already detect your CPU settings by default at"
 211                 ewarn "buildtime; this flag is used for runtime detection."
 212                 ewarn "You won't need this turned on if you are only building"
 213                 ewarn "mplayer for this system. Also, if your compile fails, try"
 214                 ewarn "disabling this use flag."
 215         fi
 216
 217         if has_version 'media-video/libav' ; then
 218                 ewarn "Please note that upstream uses media-video/ffmpeg."
 219                 ewarn "media-video/libav should be fine in theory but if you"
 220                 ewarn "experience any problem, try to move to media-video/ffmpeg."
 221         fi
 222 }
 223
 224 src_unpack() {
 225         if [[ ${PV} = *9999* ]]; then
 226                 subversion_src_unpack
 227                 cd "${WORKDIR}"
 228                 rm -rf "${WORKDIR}/${P}/ffmpeg/"
 229                 ( S="${WORKDIR}/${P}/ffmpeg/" git-2_src_unpack )
 230         else
 231                 unpack ${A}
 232         fi
 233
 234         if [[ ${PV} = *9999* ]] || [[ "${PV%_rc*}" = "${PV}" ]]; then
 235                 cd "${S}"
 236                 cp "${FILESDIR}/dump_ffmpeg.sh" . || die
 237                 chmod +x dump_ffmpeg.sh
 238                 ./dump_ffmpeg.sh || die
 239         fi
 240
 241         if ! use truetype; then
 242                 unpack font-arial-iso-8859-1.tar.bz2 \
 243                         font-arial-iso-8859-2.tar.bz2 \
 244                         font-arial-cp1250.tar.bz2
 245         fi
 246 }
 247
 248 src_prepare() {
 249         local svf=snapshot_version
 250         if [[ ${PV} = *9999* ]]; then
 251                 # Set SVN version manually
 252                 subversion_wc_info
 253                 printf "${ESVN_WC_REVISION}" > $svf
 254         fi
 255         if [ ! -f VERSION ] ; then
 256                 [ -f "$svf" ] || die "Missing ${svf}. Did you generate your snapshot with prepare_mplayer.sh?"
 257                 local sv=$(<$svf)
 258                 printf "SVN-r${sv} (Gentoo)" > VERSION
 259         fi
 260
 261         # fix path to bash executable in configure scripts
 262         sed -i -e "1c\#!${EPREFIX}/bin/bash" configure version.sh || die
 263
 264         base_src_prepare
 265
 266         # Use sane default for >=virtual/udev-197
 267         sed -i -e '/default_dvd_device/s:/dev/dvd:/dev/cdrom:' configure || die
 268 }
 269
 270 src_configure() {
 271         local myconf=""
 272         local uses i
 273
 274         # set LINGUAS
 275         [[ -n $LINGUAS ]] && LINGUAS="${LINGUAS/da/dk}"
 276         [[ -n $LINGUAS ]] && LINGUAS="${LINGUAS/zh/zh_CN}" #482968
 277
 278         # mplayer ebuild uses "use foo || --disable-foo" to forcibly disable
 279         # compilation in almost every situation. The reason for this is
 280         # because if --enable is used, it will force the build of that option,
 281         # regardless of whether the dependency is available or not.
 282
 283         ###################
 284         #Optional features#
 285         ###################
 286         # disable svga since we don't want it
 287         # disable arts since we don't have kde3
 288         # always disable internal ass
 289         # disable opus and ilbc since it only controls support in internal
 290         #         ffmpeg which we do not use
 291         myconf+="
 292                 --disable-svga --disable-svgalib_helper
 293                 --disable-ass-internal
 294                 --disable-arts
 295                 --disable-kai
 296                 --disable-libopus
 297                 --disable-libilbc
 298                 $(use_enable network networking)
 299                 $(use_enable joystick)
 300         "
 301         uses="bl bluray enca ftp rtc" # nemesi <- not working with in-tree ebuild
 302         myconf+=" --disable-nemesi" # nemesi automagic disable
 303         for i in ${uses}; do
 304                 use ${i} || myconf+=" --disable-${i}"
 305         done
 306         use bidi  || myconf+=" --disable-fribidi"
 307         use ipv6  || myconf+=" --disable-inet6"
 308         use libass || myconf+=" --disable-ass"
 309         use nut   || myconf+=" --disable-libnut"
 310         use rar   || myconf+=" --disable-unrarexec"
 311         use samba || myconf+=" --disable-smb"
 312         use lirc  || myconf+=" --disable-lirc --disable-lircc --disable-apple-ir"
 313
 314         # libcdio support: prefer libcdio over cdparanoia
 315         # don't check for cddb w/cdio
 316         if use cdio; then
 317                 myconf+=" --disable-cdparanoia"
 318         else
 319                 myconf+=" --disable-libcdio"
 320                 use cdparanoia || myconf+=" --disable-cdparanoia"
 321                 use cddb || myconf+=" --disable-cddb"
 322         fi
 323
 324         ################################
 325         # DVD read, navigation support #
 326         ################################
 327         #
 328         # dvdread - accessing a DVD
 329         # dvdnav - navigation of menus
 330         use dvd || myconf+=" --disable-dvdread"
 331         use dvdnav || myconf+=" --disable-dvdnav"
 332
 333         #############
 334         # Subtitles #
 335         #############
 336         #
 337         # SRT/ASS/SSA (subtitles) requires freetype support
 338         # freetype support requires iconv
 339         # iconv optionally can use unicode
 340         use truetype || myconf+=" --disable-freetype"
 341         use iconv || myconf+=" --disable-iconv --charset=noconv"
 342         use iconv && use unicode && myconf+=" --charset=UTF-8"
 343
 344         #####################################
 345         # DVB / Video4Linux / Radio support #
 346         #####################################
 347         myconf+=" --disable-tv-bsdbt848"
 348         # broken upstream, won't work with recent kernels
 349         myconf+=" --disable-ivtv"
 350         # gone since linux-headers-2.6.38
 351         myconf+=" --disable-tv-v4l1"
 352         if { use dvb || use v4l || use pvr || use radio; }; then
 353                 use dvb || myconf+=" --disable-dvb"
 354                 use pvr || myconf+=" --disable-pvr"
 355                 use v4l || myconf+=" --disable-tv-v4l2"
 356                 if use radio && { use dvb || use v4l; }; then
 357                         myconf+="
 358                                 --enable-radio
 359                                 $(use_enable encode radio-capture)
 360                         "
 361                 else
 362                         myconf+="
 363                                 --disable-radio-v4l2
 364                                 --disable-radio-bsdbt848
 365                         "
 366                 fi
 367         else
 368                 myconf+="
 369                         --disable-tv
 370                         --disable-tv-v4l2
 371                         --disable-radio
 372                         --disable-radio-v4l2
 373                         --disable-radio-bsdbt848
 374                         --disable-dvb
 375                         --disable-v4l2
 376                         --disable-pvr"
 377         fi
 378
 379         ##########
 380         # Codecs #
 381         ##########
 382         myconf+=" --disable-musepack" # Use internal musepack codecs for SV7 and SV8 support
 383         myconf+=" --disable-libmpeg2-internal" # always use system media-libs/libmpeg2
 384         use dts || myconf+=" --disable-libdca"
 385         if ! use mp3; then
 386                 myconf+="
 387                         --disable-mp3lame
 388                         --disable-mpg123
 389                 "
 390         fi
 391         uses="a52 bs2b dv gsm lzo rtmp vorbis"
 392         for i in ${uses}; do
 393                 use ${i} || myconf+=" --disable-lib${i}"
 394         done
 395
 396         uses="faad gif jpeg libmpeg2 live mad mng png pnm speex tga theora tremor xanim"
 397         for i in ${uses}; do
 398                 use ${i} || myconf+=" --disable-${i}"
 399         done
 400         use jpeg2k || myconf+=" --disable-libopenjpeg"
 401
 402         # Encoding
 403         uses="faac x264 xvid toolame twolame"
 404         if use encode; then
 405                 for i in ${uses}; do
 406                         use ${i} || myconf+=" --disable-${i}"
 407                 done
 408         else
 409                 myconf+=" --disable-mencoder"
 410                 for i in ${uses}; do
 411                         myconf+=" --disable-${i}"
 412                         use ${i} && elog "Useflag \"${i}\" will only be useful for encoding, i.e., with \"encode\" useflag enabled."
 413                 done
 414         fi
 415
 416         #################
 417         # Binary codecs #
 418         #################
 419         myconf+=" --disable-qtx --disable-real --disable-win32dll"
 420
 421         ################
 422         # Video Output #
 423         ################
 424         uses="directfb md5sum sdl"
 425         for i in ${uses}; do
 426                 use ${i} || myconf+=" --disable-${i}"
 427         done
 428         use aalib || myconf+=" --disable-aa"
 429         use fbcon || myconf+=" --disable-fbdev"
 430         use fbcon && use video_cards_s3virge && myconf+=" --enable-s3fb"
 431         use libcaca || myconf+=" --disable-caca"
 432         use zoran || myconf+=" --disable-zr"
 433
 434         if ! use kernel_linux || ! use video_cards_mga; then
 435                  myconf+=" --disable-mga --disable-xmga"
 436         fi
 437
 438         if use video_cards_tdfx; then
 439                 myconf+="
 440                         $(use_enable video_cards_tdfx tdfxvid)
 441                         $(use_enable fbcon tdfxfb)
 442                 "
 443         else
 444                 myconf+="
 445                         --disable-3dfx
 446                         --disable-tdfxvid
 447                         --disable-tdfxfb
 448                 "
 449         fi
 450
 451         # sun card, disable by default, see bug #258729
 452         myconf+=" --disable-xvr100"
 453
 454         ################
 455         # Audio Output #
 456         ################
 457         myconf+=" --disable-esd"
 458         uses="alsa jack ladspa nas openal"
 459         for i in ${uses}; do
 460                 use ${i} || myconf+=" --disable-${i}"
 461         done
 462         use pulseaudio || myconf+=" --disable-pulse"
 463         if ! use radio; then
 464                 use oss || myconf+=" --disable-ossaudio"
 465         fi
 466
 467         ####################
 468         # Advanced Options #
 469         ####################
 470         # Platform specific flags, hardcoded on amd64 (see below)
 471         use cpudetection && myconf+=" --enable-runtime-cpudetection"
 472
 473         uses="3dnow 3dnowext mmx mmxext sse sse2 ssse3"
 474         for i in ${uses}; do
 475                 myconf+=" $(use_enable cpu_flags_x86_${i} ${i})"
 476         done
 477
 478         uses="altivec shm"
 479         for i in ${uses}; do
 480                 myconf+=" $(use_enable ${i})"
 481         done
 482
 483         use debug && myconf+=" --enable-debug=3"
 484
 485         if use x86 && gcc-specs-pie; then
 486                 filter-flags -fPIC -fPIE
 487                 append-ldflags -nopie
 488         fi
 489
 490         ###########################
 491         # X enabled configuration #
 492         ###########################
 493         myconf+=" --disable-gui"
 494         myconf+=" --disable-vesa"
 495         uses="ggi vdpau xinerama xv"
 496         for i in ${uses}; do
 497                 use ${i} || myconf+=" --disable-${i}"
 498         done
 499         use dga          || myconf+=" --disable-dga1 --disable-dga2"
 500         use opengl       || myconf+=" --disable-gl"
 501         use osdmenu      && myconf+=" --enable-menu"
 502         use vidix        || myconf+=" --disable-vidix --disable-vidix-pcidb"
 503         use xscreensaver || myconf+=" --disable-xss"
 504         use X            || myconf+=" --disable-x11"
 505         if use xvmc; then
 506                 myconf+=" --enable-xvmc --with-xvmclib=XvMCW"
 507         else
 508                 myconf+=" --disable-xvmc"
 509         fi
 510
 511         ############################
 512         # OSX (aqua) configuration #
 513         ############################
 514         if use aqua; then
 515                 myconf+="
 516                         --enable-macosx-finder
 517                         --enable-macosx-bundle
 518                 "
 519         fi
 520
 521         ./configure \
 522                 --cc="$(tc-getCC)" \
 523                 --host-cc="$(tc-getBUILD_CC)" \
 524                 --prefix="${EPREFIX}/usr" \
 525                 --bindir="${EPREFIX}/usr/bin" \
 526                 --libdir="${EPREFIX}/usr/$(get_libdir)" \
 527                 --confdir="${EPREFIX}/etc/mplayer" \
 528                 --datadir="${EPREFIX}/usr/share/mplayer${namesuf}" \
 529                 --mandir="${EPREFIX}/usr/share/man" \
 530                 --disable-ffmpeg_a \
 531                 ${myconf} || die
 532 }
 533
 534 src_compile() {
 535         base_src_compile
 536         # Build only user-requested docs if they're available.
 537         if use doc ; then
 538                 # select available languages from $LINGUAS
 539                 local ALLOWED_LINGUAS="cs de en es fr hu it pl ru zh_CN"
 540                 local BUILT_DOCS=""
 541                 for i in ${LINGUAS} ; do
 542                         has ${i} ${ALLOWED_LINGUAS} && BUILT_DOCS+=" ${i}"
 543                 done
 544                 if [[ -z $BUILT_DOCS ]]; then
 545                         emake -j1 html-chunked
 546                 else
 547                         for i in ${BUILT_DOCS}; do
 548                                 emake -j1 html-chunked-${i}
 549                         done
 550                 fi
 551         fi
 552 }
 553
 554 src_install() {
 555         local i
 556
 557         emake \
 558                 DESTDIR="${D}" \
 559                 INSTALLSTRIP="" \
 560                 install
 561
 562         dodoc AUTHORS Changelog Copyright README etc/codecs.conf
 563
 564         docinto tech/
 565         dodoc DOCS/tech/{*.txt,MAINTAINERS,mpsub.sub,playtree,TODO,wishlist}
 566         docinto TOOLS/
 567         dodoc -r TOOLS
 568         docinto tech/mirrors/
 569         dodoc DOCS/tech/mirrors/*
 570
 571         if use doc; then
 572                 docinto html/
 573                 dohtml -r "${S}"/DOCS/HTML/*
 574         fi
 575
 576         if ! use truetype; then
 577                 dodir /usr/share/mplayer/fonts
 578                 # Do this generic, as the mplayer people like to change the structure
 579                 # of their zips ...
 580                 for i in $(find "${WORKDIR}/" -type d -name 'font-arial-*'); do
 581                         cp -pPR "${i}" "${ED}/usr/share/mplayer/fonts"
 582                 done
 583                 # Fix the font symlink ...
 584                 rm -rf "${ED}/usr/share/mplayer/font"
 585                 dosym fonts/font-arial-14-iso-8859-1 /usr/share/mplayer/font
 586         fi
 587
 588         insinto /etc/mplayer
 589         newins "${S}/etc/example.conf" mplayer.conf
 590         cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
 591 # Config options can be section specific, global
 592 # options should go in the default section
 593 [default]
 594 _EOF_
 595         doins "${S}/etc/input.conf"
 596         if use osdmenu; then
 597                 doins "${S}/etc/menu.conf"
 598         fi
 599
 600         if use truetype; then
 601                 cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
 602 fontconfig=1
 603 subfont-osd-scale=4
 604 subfont-text-scale=3
 605 _EOF_
 606         fi
 607
 608         # bug 256203
 609         if use rar; then
 610                 cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
 611 unrarexec=${EPREFIX}/usr/bin/unrar
 612 _EOF_
 613         fi
 614
 615         dosym ../../../etc/mplayer/mplayer.conf /usr/share/mplayer/mplayer.conf
 616         newbin "${S}/TOOLS/midentify.sh" midentify
 617 }
 618
 619 pkg_preinst() {
 620         [[ -d ${EROOT}/usr/share/mplayer/Skin/default ]] && \
 621                 rm -rf "${EROOT}/usr/share/mplayer/Skin/default"
 622 }
 623
 624 pkg_postrm() {
 625         # Cleanup stale symlinks
 626         [ -L "${EROOT}/usr/share/mplayer/font" -a \
 627                         ! -e "${EROOT}/usr/share/mplayer/font" ] && \
 628                 rm -f "${EROOT}/usr/share/mplayer/font"
 629
 630         [ -L "${EROOT}/usr/share/mplayer/subfont.ttf" -a \
 631                         ! -e "${EROOT}/usr/share/mplayer/subfont.ttf" ] && \
 632                 rm -f "${EROOT}/usr/share/mplayer/subfont.ttf"
 633 }