media-video/minitube/minitube-2.0.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 PLOCALES="ar ca ca_ES da de_DE el en es es_AR es_ES fi fi_FI fr he_IL hr hu
   7 ia it jv nl pl pl_PL pt_BR ro ru sk sl tr zh_CN"
   8
   9 inherit l10n qt4-r2
  10
  11 DESCRIPTION="Qt4 YouTube Client"
  12 HOMEPAGE="http://flavio.tordini.org/minitube"
  13 SRC_URI="http://flavio.tordini.org/files/${PN}/${P}.tar.gz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE="debug gstreamer kde"
  19
  20 DEPEND=">=dev-qt/qtgui-4.6:4[accessibility,gtkstyle]
  21         >=dev-qt/qtdbus-4.6:4
  22         kde? ( || ( media-libs/phonon[gstreamer?,qt4] >=dev-qt/qtphonon-4.6:4 ) )
  23         !kde? ( || ( >=dev-qt/qtphonon-4.6:4 media-libs/phonon[gstreamer?,qt4] ) )
  24         gstreamer? (
  25                 media-plugins/gst-plugins-soup:0.10
  26                 media-plugins/gst-plugins-ffmpeg:0.10
  27                 media-plugins/gst-plugins-faac:0.10
  28                 media-plugins/gst-plugins-faad:0.10
  29                 media-plugins/gst-plugins-theora
  30         )
  31 "
  32 RDEPEND="${DEPEND}"
  33
  34 S=${WORKDIR}/${PN}
  35
  36 DOCS="AUTHORS CHANGES TODO"
  37
  38 #455976
  39 PATCHES=( "${FILESDIR}"/${P}-disable-updates.patch )
  40
  41 src_prepare() {
  42         qt4-r2_src_prepare
  43
  44         # Remove unneeded translations
  45         local trans=
  46         for x in $(l10n_get_locales); do
  47                 trans+="${x}.ts "
  48         done
  49         if [[ -n ${trans} ]]; then
  50                 sed -i -e "/^TRANSLATIONS/s/+=.*/+=${trans}/" locale/locale.pri || die
  51         fi
  52         # gcc-4.7. Bug #422977. Will probably be fixed
  53         # once ubuntu moves to gcc-4.7
  54         epatch "${FILESDIR}"/${PN}-1.9-gcc47.patch
  55 }
  56
  57 src_install() {
  58         qt4-r2_src_install
  59         newicon images/app.png minitube.png
  60 }