media-video/gpac/gpac-9999.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6
   7 if [[ ${PV} == *9999 ]] ; then
   8         SCM="git-r3"
   9         EGIT_REPO_URI="https://github.com/gpac/gpac"
  10         KEYWORDS=""
  11 else
  12         SRC_URI="https://github.com/gpac/gpac/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  13         KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
  14 fi
  15
  16 inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
  17
  18 DESCRIPTION="GPAC is an implementation of the MPEG-4 Systems standard developed from scratch in ANSI C"
  19 HOMEPAGE="http://gpac.wp.mines-telecom.fr/"
  20
  21 LICENSE="GPL-2"
  22 SLOT="0"
  23 IUSE="a52 aac alsa debug dvb ffmpeg ipv6 jack jpeg jpeg2k mad opengl oss png
  24         pulseaudio sdl ssl static-libs theora truetype vorbis xml xvid X"
  25
  26 RDEPEND="
  27         a52? ( media-libs/a52dec )
  28         aac? ( >=media-libs/faad2-2.0 )
  29         alsa? ( media-libs/alsa-lib )
  30         dvb? ( media-tv/linuxtv-dvb-apps )
  31         ffmpeg? ( virtual/ffmpeg )
  32         jack? ( media-sound/jack-audio-connection-kit )
  33         jpeg? ( virtual/jpeg )
  34         mad? ( >=media-libs/libmad-0.15.1b )
  35         opengl? ( virtual/opengl media-libs/freeglut virtual/glu )
  36         >=media-libs/libogg-1.1
  37         png? ( >=media-libs/libpng-1.4 )
  38         vorbis? ( >=media-libs/libvorbis-1.1 )
  39         theora? ( media-libs/libtheora )
  40         truetype? ( >=media-libs/freetype-2.1.4 )
  41         xml? ( >=dev-libs/libxml2-2.6.0 )
  42         xvid? ( >=media-libs/xvid-1.0.1 )
  43         sdl? ( media-libs/libsdl )
  44         jpeg2k? ( media-libs/openjpeg:0 )
  45         ssl? ( dev-libs/openssl )
  46         pulseaudio? ( media-sound/pulseaudio )
  47         X? (
  48                 x11-libs/libXt
  49                 x11-libs/libX11
  50                 x11-libs/libXv
  51                 x11-libs/libXext
  52         )"
  53 # disabled upstream, see applications/Makefile
  54 # wxwidgets? ( =x11-libs/wxGTK-2.8* )
  55
  56 DEPEND="${RDEPEND}"
  57
  58 my_use() {
  59         local flag="$1" pflag="${2:-$1}"
  60         if use ${flag}; then
  61                 echo "--use-${pflag}=system"
  62         else
  63                 echo "--use-${pflag}=no"
  64         fi
  65 }
  66
  67 src_prepare() {
  68         epatch  "${FILESDIR}"/110_all_implicitdecls.patch \
  69                         "${FILESDIR}"/${PN}-0.5.3-static-libs.patch \
  70                         "${FILESDIR}"/${PN}-0.5.2-gf_isom_set_pixel_aspect_ratio.patch
  71         sed -i -e "s:\(--disable-.*\)=\*):\1):" configure || die
  72 }
  73
  74 src_configure() {
  75         tc-export CC CXX AR RANLIB
  76
  77         econf \
  78                 --enable-svg \
  79                 --enable-pic \
  80                 --disable-amr \
  81                 --use-js=no \
  82                 --use-ogg=system \
  83                 $(use_enable alsa) \
  84                 $(use_enable debug) \
  85                 $(use_enable ipv6) \
  86                 $(use_enable jack jack yes) \
  87                 $(use_enable opengl) \
  88                 $(use_enable oss oss-audio) \
  89                 $(use_enable pulseaudio pulseaudio yes) \
  90                 $(use_enable sdl) \
  91                 $(use_enable ssl) \
  92                 $(use_enable static-libs static-lib) \
  93                 $(use_enable X x11) $(use_enable X x11-shm) $(use_enable X x11-xv) \
  94                 --disable-wx \
  95                 $(my_use a52) \
  96                 $(my_use aac faad) \
  97                 $(my_use dvb dvbx) \
  98                 $(my_use ffmpeg) \
  99                 $(my_use jpeg) \
 100                 $(my_use jpeg2k openjpeg) \
 101                 $(my_use mad) \
 102                 $(my_use png) \
 103                 $(my_use theora) \
 104                 $(my_use truetype ft) \
 105                 $(my_use vorbis) \
 106                 $(my_use xvid) \
 107                 --extra-cflags="${CFLAGS}" \
 108                 --cc="$(tc-getCC)" \
 109                 --libdir="/$(get_libdir)" \
 110                 --verbose
 111 }
 112
 113 src_install() {
 114         emake STRIP="true" DESTDIR="${D}" install
 115         emake STRIP="true" DESTDIR="${D}" install-lib
 116         dodoc AUTHORS BUGS Changelog README.md TODO
 117         dodoc doc/*.txt
 118         dohtml doc/*.html
 119 }