media-video/gaupol/gaupol-1.7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7
   8 inherit distutils-r1 virtualx xdg-utils
   9
  10 DESCRIPTION="A subtitle editor for text-based subtitles"
  11 HOMEPAGE="https://otsaloma.io/gaupol/"
  12 SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 arm64 x86"
  17 IUSE="spell test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         app-text/iso-codes
  22         dev-python/chardet[${PYTHON_USEDEP}]
  23         dev-python/pygobject:3[${PYTHON_USEDEP}]
  24         x11-libs/gtk+:3[introspection]
  25         spell? ( app-text/gspell[introspection] )
  26 "
  27 DEPEND="
  28         sys-devel/gettext
  29         test? (
  30                 ${RDEPEND}
  31                 app-dicts/myspell-en
  32                 app-text/enchant[hunspell]
  33                 app-text/gspell[introspection]
  34                 dev-python/pytest[${PYTHON_USEDEP}]
  35         )
  36 "
  37
  38 DOCS=( AUTHORS.md NEWS.md TODO.md README.md README.aeidon.md )
  39
  40 PATCHES=( "${FILESDIR}/${P}-fix-tests.patch" )
  41
  42 python_test() {
  43         virtx pytest -vv
  44 }
  45
  46 pkg_postinst() {
  47         xdg_desktop_database_update
  48         xdg_icon_cache_update
  49         if [[ -z ${REPLACING_VERSIONS} ]]; then
  50                 elog "Previewing support requires MPV, MPlayer or VLC."
  51                 if use spell; then
  52                         elog ""
  53                         elog "Spell-checking requires a dictionary, any of app-dicts/myspell-*"
  54                         elog "or app-text/aspell with the appropriate L10N variable."
  55                         elog ""
  56                         elog "Additionally, make sure that app-text/enchant has the correct flags enabled:"
  57                         elog "USE=hunspell for myspell dictionaries and USE=aspell for aspell dictionaries."
  58                 fi
  59         fi
  60 }
  61
  62 pkg_postrm() {
  63         xdg_desktop_database_update
  64         xdg_icon_cache_update
  65 }