media-video/gaupol/gaupol-1.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7
   8 inherit distutils-r1 gnome2-utils virtualx xdg-utils
   9
  10 DESCRIPTION="A subtitle editor for text-based subtitles"
  11 HOMEPAGE="https://otsaloma.io/gaupol/"
  12 SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 arm64 x86"
  17 IUSE="spell test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         app-text/iso-codes
  22         dev-python/chardet[${PYTHON_USEDEP}]
  23         dev-python/pygobject:3[${PYTHON_USEDEP}]
  24         x11-libs/gtk+:3[introspection]
  25         spell? (
  26                 app-text/gtkspell:3
  27                 >=dev-python/pyenchant-1.4[${PYTHON_USEDEP}]
  28         )
  29 "
  30 DEPEND="
  31         sys-devel/gettext
  32         test? (
  33                 ${RDEPEND}
  34                 dev-python/pyenchant[${PYTHON_USEDEP}]
  35                 dev-python/pytest[${PYTHON_USEDEP}]
  36         )
  37 "
  38
  39 DOCS=( AUTHORS.md NEWS.md TODO.md README.md README.aeidon.md )
  40
  41 python_test() {
  42         virtx pytest -vv
  43 }
  44
  45 pkg_postinst() {
  46         xdg_desktop_database_update
  47         xdg_mimeinfo_database_update
  48         gnome2_icon_cache_update
  49         if [[ -z ${REPLACING_VERSIONS} ]]; then
  50                 elog "Previewing support needs MPV, MPlayer or VLC."
  51
  52                 if use spell; then
  53                         elog "Additionally, spell-checking requires a dictionary, any of"
  54                         elog "Aspell/Pspell, Ispell, MySpell, Uspell, Hspell or AppleSpell."
  55                 fi
  56         fi
  57 }
  58
  59 pkg_postrm() {
  60         xdg_desktop_database_update
  61         xdg_mimeinfo_database_update
  62         gnome2_icon_cache_update
  63 }