media-video/ffmpeg2theora/ffmpeg2theora-0.29-r2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils toolchain-funcs scons-utils
   7
   8 DESCRIPTION="A simple converter to create Ogg Theora files"
   9 HOMEPAGE="http://www.v2v.cc/~j/ffmpeg2theora/"
  10 SRC_URI="http://www.v2v.cc/~j/${PN}/downloads/${P}.tar.bz2"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
  15 IUSE="kate libav"
  16
  17 RDEPEND="
  18         !libav? ( media-video/ffmpeg:0= )
  19         libav? ( media-libs/libpostproc:0=
  20                 media-video/libav:0= )
  21         >=media-libs/libvorbis-1.1
  22         >=media-libs/libogg-1.1
  23         >=media-libs/libtheora-1.1[encode]
  24         kate? ( >=media-libs/libkate-0.3.7 )"
  25 DEPEND="${RDEPEND}
  26         virtual/pkgconfig"
  27
  28 src_prepare() {
  29         epatch \
  30                 "${FILESDIR}"/${P}-swr.patch \
  31                 "${FILESDIR}"/${P}-ffmpeg2.patch \
  32                 "${FILESDIR}"/${P}-underlinking.patch
  33         has_version '>=media-video/ffmpeg-2.9' && epatch "${FILESDIR}/${P}-ffmpeg29.patch"
  34 }
  35
  36 src_configure() {
  37         myesconsargs=(
  38                 APPEND_CCFLAGS="${CFLAGS}"
  39                 APPEND_LINKFLAGS="${LDFLAGS}"
  40                 prefix=/usr
  41                 mandir=PREFIX/share/man
  42                 libkate=$(usex kate 1 0)
  43                 )
  44 }
  45
  46 src_compile() {
  47         escons
  48 }
  49
  50 src_install() {
  51         escons destdir="${D}" install
  52         dodoc AUTHORS ChangeLog README subtitles.txt TODO
  53 }