media-video/dvdstyler/dvdstyler-3.0.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 MY_P=${P/dvds/DVDS}
   7 WX_GTK_VER=3.0
   8
   9 inherit wxwidgets eutils
  10
  11 DESCRIPTION="A cross-platform free DVD authoring application"
  12 HOMEPAGE="http://www.dvdstyler.org/"
  13 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="debug libav +udev"
  19
  20 COMMON_DEPEND="
  21         >=app-cdr/dvd+rw-tools-7.1
  22         media-libs/libexif:=
  23         >=media-libs/wxsvg-1.5.11:=
  24         >=media-video/dvdauthor-0.7.1
  25         >=media-video/xine-ui-0.99.7
  26         virtual/cdrtools
  27         libav? ( >=media-video/libav-9:0=[encode] )
  28         !libav? ( >=media-video/ffmpeg-2.6:0=[encode] )
  29         virtual/jpeg:0
  30         x11-libs/wxGTK:${WX_GTK_VER}=[gstreamer,X]
  31         sys-apps/dbus
  32         udev? ( >=virtual/libudev-215:= )
  33 "
  34 RDEPEND="${COMMON_DEPEND}
  35         >=app-cdr/dvdisaster-0.72.4
  36         media-video/mjpegtools
  37 "
  38 DEPEND="${COMMON_DEPEND}
  39         app-arch/zip
  40         app-text/xmlto
  41         sys-devel/gettext
  42         virtual/yacc
  43         virtual/pkgconfig
  44 "
  45
  46 S="${WORKDIR}/${MY_P}"
  47
  48 src_prepare() {
  49         epatch "${FILESDIR}/ffmpeg4.patch"
  50
  51         need-wxwidgets unicode
  52         # disable obsolete GNOME 2.x libraries wrt #508854
  53         sed -i -e '/PKG_CONFIG/s:libgnomeui-2.0:dIsAbLeAuToMaGiC&:' configure || die
  54         # rmdir: failed to remove `tempfoobar': Directory not empty
  55         sed -i -e '/rmdir "$$t"/d' docs/Makefile.in || die
  56         # fix underlinking wrt #367863
  57         sed -i -e 's:@LIBS@:& -ljpeg:' wxVillaLib/Makefile.in || die
  58         # silence desktop-file-validate QA check
  59         sed -i \
  60                 -e '/Icon/s:.png::' -e '/^Encoding/d' -e '/Categories/s:Application;::' \
  61                 data/dvdstyler.desktop || die
  62 }
  63
  64 src_configure() {
  65         econf \
  66                 --docdir=/usr/share/doc/${PF} \
  67                 $(use_enable debug) \
  68                 --with-wx-config=${WX_CONFIG}
  69 }
  70
  71 src_install() {
  72         default
  73         rm -f "${ED}"/usr/share/doc/${PF}/{COPYING*,INSTALL*}
  74 }