media-video/dvdauthor/dvdauthor-0.7.2-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils flag-o-matic toolchain-funcs
   6
   7 DESCRIPTION="Tools for generating DVD files to be played on standalone DVD players"
   8 HOMEPAGE="http://dvdauthor.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="amd64 ppc ppc64 ~sparc x86"
  14 IUSE="graphicsmagick +imagemagick"
  15 REQUIRED_USE="^^ ( graphicsmagick imagemagick )"
  16
  17 RDEPEND=">=dev-libs/fribidi-0.19.2
  18         dev-libs/libxml2
  19         >=media-libs/freetype-2
  20         media-libs/libdvdread
  21         media-libs/libpng:0=
  22         graphicsmagick? ( media-gfx/graphicsmagick:= )
  23         imagemagick? ( media-gfx/imagemagick:= )"
  24 DEPEND="${RDEPEND}
  25         virtual/pkgconfig"
  26
  27 S="${WORKDIR}/${PN}"
  28
  29 DOCS=( AUTHORS ChangeLog README TODO )
  30
  31 PATCHES=( "${FILESDIR}/${PN}-freetype_pkgconfig.patch" )
  32
  33 src_prepare() {
  34         default
  35
  36         eautoreconf
  37
  38         if use imagemagick && has_version '>=media-gfx/imagemagick-7.0.1.0' ; then
  39                 eapply "${FILESDIR}/${PN}-0.7.2-imagemagick7.patch"
  40         fi
  41
  42         if use graphicsmagick ; then
  43                 sed -i -e 's:ExportImagePixels:dIsAbLeAuToMaGiC&:' configure \
  44                         || die
  45         fi
  46 }
  47
  48 src_configure() {
  49         use graphicsmagick && \
  50                 append-cppflags "$($(tc-getPKG_CONFIG) --cflags GraphicsMagick)" #459976
  51         append-cppflags "$($(tc-getPKG_CONFIG) --cflags fribidi)" #417041
  52         econf
  53 }