media-video/dvdauthor/dvdauthor-0.7.1-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils flag-o-matic toolchain-funcs
   6
   7 DESCRIPTION="Tools for generating DVD files to be played on standalone DVD players"
   8 HOMEPAGE="http://dvdauthor.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="amd64 ppc ppc64 sparc x86"
  14 IUSE="graphicsmagick +imagemagick"
  15 REQUIRED_USE="^^ ( graphicsmagick imagemagick )"
  16
  17 RDEPEND=">=dev-libs/fribidi-0.19.2
  18         dev-libs/libxml2
  19         >=media-libs/freetype-2
  20         media-libs/libdvdread
  21         media-libs/libpng:0=
  22         graphicsmagick? ( media-gfx/graphicsmagick:= )
  23         imagemagick? ( media-gfx/imagemagick:= )"
  24 DEPEND="${RDEPEND}
  25         virtual/pkgconfig"
  26
  27 S=${WORKDIR}/${PN}
  28
  29 DOCS=( AUTHORS ChangeLog README TODO )
  30
  31 PATCHES=(
  32         "${FILESDIR}/${P}-glibc220.patch"
  33 )
  34
  35 src_prepare() {
  36         default
  37         if use graphicsmagick ; then
  38                 sed -i -e 's:ExportImagePixels:dIsAbLeAuToMaGiC&:' configure \
  39                         || die
  40         fi
  41 }
  42
  43 src_configure() {
  44         use graphicsmagick && \
  45                 append-cppflags "$($(tc-getPKG_CONFIG) --cflags GraphicsMagick)" #459976
  46         append-cppflags "$($(tc-getPKG_CONFIG) --cflags fribidi)" #417041
  47         econf
  48 }