media-video/2mandvd/2mandvd-1.8.5.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 LANGS="cs de en it ru"
   7
   8 inherit qt4-r2
   9
  10 MY_PN="2ManDVD"
  11
  12 DESCRIPTION="The successor of ManDVD"
  13 HOMEPAGE="http://kde-apps.org/content/show.php?content=99450"
  14 SRC_URI="http://download.tuxfamily.org/${PN}/${MY_PN}-${PV}.tar.gz"
  15
  16 LICENSE="GPL-2+"
  17 SLOT="0"
  18 KEYWORDS="amd64 x86"
  19 IUSE="debug libav"
  20
  21 DEPEND="libav? ( media-video/libav:= )
  22         !libav? ( media-video/ffmpeg:0= )
  23         media-libs/libsdl
  24         virtual/glu
  25         virtual/opengl
  26         dev-qt/qtcore:4
  27         dev-qt/qtgui:4
  28         dev-qt/qtopengl:4
  29 "
  30 RDEPEND="${DEPEND}
  31         || ( app-cdr/cdrkit app-cdr/cdrtools )
  32         dev-lang/perl
  33         media-fonts/dejavu
  34         media-gfx/exif
  35         media-libs/netpbm
  36         media-sound/sox
  37         media-video/dvdauthor
  38         media-video/ffmpegthumbnailer
  39         media-video/mjpegtools
  40         media-video/mplayer[encode]
  41 "
  42
  43 S=${WORKDIR}/${MY_PN}
  44
  45 PATCHES=(
  46         "${FILESDIR}/${PN}-1.7.3-libav.patch"
  47         "${FILESDIR}/${PN}-1.8.5-libavformat54.patch"
  48 )
  49
  50 src_prepare() {
  51         # Clean backup files
  52         find . -name "*~" -delete || die
  53
  54         # Delete useless chmod that violates the sandbox
  55         sed -i -e '/chmod/d' ${MY_PN}.pro || die
  56
  57         # Fix desktop file
  58         sed -i -e '/^Categories=/s/GNOME;AudioVideo;//' ${MY_PN}.desktop || die
  59
  60         qt4-r2_src_prepare
  61 }
  62
  63 pkg_postinst() {
  64         elog "You may wish to install media-video/xine-ui and/or build"
  65         elog "media-sound/sox with USE=mad for improved media handling support."
  66 }