media-tv/xmltv/xmltv-0.5.70.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit perl-module
   7
   8 DESCRIPTION="Set of utilities to manage TV listings stored in the XMLTV format"
   9 HOMEPAGE="http://xmltv.org"
  10 SRC_URI="mirror://sourceforge/xmltv/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm ~ppc x86 ~x86-linux"
  15
  16 IUSE="ar ch-search dk dtvla es-laguiatv eu-dotmedia eu-epg fi fi-sv
  17 fr fr-kazer huro il is it na-dd na-dtv na-tvmedia nl no-gf pt-meo se-swedb
  18 se-tvzon tr uk-bleb uk-tvguide tv-check tv-combiner tv-pick-cgi zz-sdjson"
  19
  20 RDEPEND=">=dev-perl/libwww-perl-5.65
  21         >=dev-perl/XML-Parser-2.34
  22         >=dev-perl/XML-Twig-3.10
  23         >=dev-perl/Date-Manip-5.42
  24         >=dev-perl/XML-Writer-0.6
  25         virtual/perl-Memoize
  26         virtual/perl-Storable
  27         >=dev-perl/Lingua-Preferred-0.2.4
  28         >=dev-perl/Term-ProgressBar-2.03
  29         virtual/perl-IO-Compress
  30         dev-perl/Unicode-String
  31         dev-perl/TermReadKey
  32         dev-perl/File-Slurp
  33         >=dev-lang/perl-5.6.1
  34         dev-perl/XML-LibXML
  35         dev-perl/XML-TreePP
  36 "
  37 DEPEND="${RDEPEND}
  38         ar? ( dev-perl/HTML-Tree >=dev-perl/HTML-Parser-3.34 dev-perl/HTTP-Cookies dev-perl/TimeDate )
  39         ch-search? ( dev-perl/HTML-Tree >=dev-perl/HTML-Parser-3.34 )
  40         dk? ( dev-perl/JSON dev-perl/IO-stringy dev-perl/DateTime )
  41         dtvla? ( dev-perl/HTML-Tree dev-perl/HTTP-Cookies dev-perl/TimeDate )
  42         es-laguiatv? ( dev-perl/HTML-Tree )
  43         eu-dotmedia? ( dev-perl/XML-LibXML dev-perl/IO-stringy dev-perl/HTTP-Cache-Transparent )
  44         eu-epg? ( dev-perl/Archive-Zip dev-perl/DateTime-Format-Strptime >=dev-perl/HTML-Parser-3.34 dev-perl/IO-stringy )
  45         fi? ( dev-perl/HTML-Tree )
  46         fi-sv? ( dev-perl/IO-stringy dev-perl/HTML-Tree dev-perl/DateTime )
  47         fr? ( dev-perl/DateTime-TimeZone dev-perl/HTML-Tree dev-perl/DateTime >=dev-perl/HTML-Parser-3.34 )
  48         huro? ( dev-perl/HTML-Tree )
  49         is? ( dev-perl/XML-DOM dev-perl/XML-LibXSLT )
  50         na-dd? ( dev-perl/SOAP-Lite )
  51         na-dtv? ( >=dev-perl/HTML-Parser-3.34 dev-perl/DateTime dev-perl/HTTP-Cookies )
  52         na-tvmedia? ( dev-perl/XML-LibXML )
  53         nl? ( dev-perl/HTTP-Cache-Transparent dev-perl/HTML-Tree dev-perl/DateTime >=dev-perl/HTML-Parser-3.34 dev-perl/TimeDate )
  54         pt-meo? ( dev-perl/XML-LibXML dev-perl/DateTime )
  55         se-swedb? ( dev-perl/XML-LibXML dev-perl/IO-stringy dev-perl/HTTP-Cache-Transparent )
  56         se-tvzon? ( dev-perl/XML-LibXML dev-perl/IO-stringy dev-perl/HTTP-Cache-Transparent )
  57         tr? ( dev-perl/URI dev-perl/HTTP-Cache-Transparent dev-perl/DateTime dev-perl/HTTP-Cookies dev-perl/TimeDate )
  58         uk-bleb? ( dev-perl/IO-stringy dev-perl/Archive-Zip )
  59         uk-tvguide? ( dev-perl/HTML-Tree dev-perl/URI dev-perl/HTTP-Cache-Transparent dev-perl/DateTime dev-perl/TimeDate )
  60         zz-sdjson? ( dev-perl/DateTime-Format-ISO8601 virtual/perl-Digest-SHA dev-perl/JSON dev-perl/List-MoreUtils dev-perl/libwww-perl virtual/perl-Storable dev-perl/Try-Tiny )
  61         tv-check? ( dev-perl/Tk dev-perl/Tk-TableMatrix )
  62         tv-combiner? ( dev-perl/XML-LibXML )
  63 "
  64
  65 PREFIX="/usr"
  66
  67 pkg_setup() {
  68         # Uses Data::Manip in various places which can fail
  69         # if TZ is still set to Factory as it is in stock gentoo
  70         # install media
  71         export TZ=UTC
  72 }
  73
  74 src_prepare() {
  75         default
  76
  77         sed -i \
  78                 -e "s:\$VERSION = '${PV}':\$VERSION = '${PVR}':" \
  79                 -e "/^@docs/s:doc/COPYING ::" \
  80                 Makefile.PL || die
  81 }
  82
  83 src_configure() {
  84         make_config() {
  85                 # Never except default configuration
  86                 echo "no"
  87
  88                 # Enable Agentina
  89                 usex ar
  90                 # Enable Switzerland Search
  91                 usex ch-search
  92                 # Enable Denmark
  93                 usex dk
  94                 # Enable Latin America
  95                 usex dtvla
  96                 # Enable Spain
  97                 usex es-laguiatv
  98                 # Enable EU xmltv.se
  99                 usex eu-dotmedia
 100                 # Enable EU epgdata.com
 101                 usex eu-epg
 102                 # Enable Finland
 103                 usex fi
 104                 # Enable Swedish listings in Finland
 105                 usex fi-sv
 106                 # Enable France
 107                 usex fr
 108                 # Enable France EPG from kazer.org
 109                 usex fr-kazer
 110                 # Enable Hungary and Romania
 111                 usex huro
 112                 # Enable Israel
 113                 usex il
 114                 # Enable Iceland
 115                 usex is
 116                 # Enable Italy
 117                 usex it
 118                 # Enable Italy from DVB-S stream
 119                 echo "no" # missing Linux::DVB
 120                 # Enable North America using DataDirect
 121                 usex na-dd
 122                 # Enable North America from directv.com
 123                 usex na-dtv
 124                 # Enable North America XMLTVListings.com
 125                 usex na-tvmedia
 126                 # Enable Netherlands
 127                 usex nl
 128                 # Enable Portugal EPG from sappo.pt
 129                 usex pt-meo
 130                 # Enable Sweden
 131                 usex se-swedb
 132                 # Enable Sweeden Alternative
 133                 usex se-tvzon
 134                 # Enable Turkey
 135                 usex tr
 136                 # Enable UK fast alternative grabber
 137                 usex uk-bleb
 138                 # Enable UK/Ireland TV Guide
 139                 usex uk-tvguide
 140                 # Enable Schedules Direct JSON
 141                 usex zz-sdjson
 142                 # Enable Schedules Direct JSON (SQLite version)
 143                 echo "no" # TODO
 144                 # Enable GUI checking.
 145                 usex tv-check
 146                 # Enable combiner
 147                 usex tv-combiner
 148                 # Enable CGI support
 149                 usex tv-pick-cgi
 150         }
 151
 152         pm_echovar=`make_config`
 153         perl-module_src_configure
 154 }
 155
 156 src_install() {
 157         # actually make test should be unneeded, but if non na grabbers
 158         # start to not install remove comment below
 159         #make test
 160         #make
 161
 162         # to bypass build issue
 163         #make DESTDIR=${D} install || die "error installing"
 164
 165         perl-module_src_install
 166
 167         local i
 168         for i in $(grep -rl "${D}" "${D}"); do
 169                 sed -e "s:${D}::g" -i "${i}" || die
 170         done
 171
 172         if use tv-pick-cgi; then
 173                 dobin choose/tv_pick/tv_pick_cgi
 174         fi
 175 }
 176
 177 pkg_postinst() {
 178         if use tv-pick-cgi; then
 179                 elog "To use tv_pick_cgi, please link it from /usr/bin/tv_pick_cgi"
 180                 elog "to where the ScriptAlias directive is configured."
 181         fi
 182 }