media-tv/v4l-utils/v4l-utils-1.10.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils flag-o-matic udev
   6
   7 DESCRIPTION="Separate utilities ebuild from upstream v4l-utils package"
   8 HOMEPAGE="http://git.linuxtv.org/v4l-utils.git"
   9 SRC_URI="http://linuxtv.org/downloads/v4l-utils/${P}.tar.bz2"
  10
  11 LICENSE="GPL-2+ LGPL-2.1+"
  12 SLOT="0"
  13 KEYWORDS="alpha amd64 ~arm ~hppa ppc ~ppc64 ~sparc x86"
  14 IUSE="qt5 udev"
  15
  16 RDEPEND=">=media-libs/libv4l-${PV}
  17         qt5? (
  18                 dev-qt/qtcore:5
  19                 dev-qt/qtgui:5
  20                 dev-qt/qtopengl:5
  21                 virtual/opengl
  22                 media-libs/alsa-lib
  23         )
  24         udev? ( virtual/libudev )
  25         !media-tv/v4l2-ctl
  26         !<media-tv/ivtv-utils-1.4.0-r2"
  27 DEPEND="${RDEPEND}
  28         sys-devel/gettext
  29         virtual/pkgconfig"
  30
  31 src_prepare() {
  32         eapply "${FILESDIR}"/${PN}-1.6.2-sysmacros.patch #580910
  33         eapply_user
  34 }
  35
  36 src_configure() {
  37         if use qt5; then
  38                 append-cxxflags -std=c++11
  39                 local qt5_paths=( \
  40                         MOC="$(pkg-config --variable=host_bins Qt5Core)/moc" \
  41                         UIC="$(pkg-config --variable=host_bins Qt5Core)/uic" \
  42                         RCC="$(pkg-config --variable=host_bins Qt5Core)/rcc" \
  43                 )
  44         fi
  45         # Hard disable the flags that apply only to the libs.
  46         econf \
  47                 --disable-static \
  48                 $(use_enable qt5 qv4l2) \
  49                 $(use_with udev libudev) \
  50                 --with-udevdir="$(get_udevdir)" \
  51                 --without-jpeg \
  52                 "${qt5_paths[@]}"
  53 }
  54
  55 src_install() {
  56         emake -C utils DESTDIR="${D}" install
  57         emake -C contrib DESTDIR="${D}" install
  58
  59         dodoc README
  60         newdoc utils/libv4l2util/TODO TODO.libv4l2util
  61         newdoc utils/libmedia_dev/README README.libmedia_dev
  62         newdoc utils/dvb/README README.dvb
  63         newdoc utils/xc3028-firmware/README README.xc3028-firmware
  64         newdoc utils/v4l2-compliance/fixme.txt fixme.txt.v4l2-compliance
  65 }