media-tv/linuxtv-dvb-apps/linuxtv-dvb-apps-1.1.1.20140321.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit toolchain-funcs vcs-snapshot
   7
   8 HOMEPAGE="https://www.linuxtv.org/"
   9 DESCRIPTION="Small utils for DVB to scan, zap, view signal strength"
  10 SRC_URI="https://www.linuxtv.org/hg/dvb-apps/archive/3d43b280298c.tar.bz2 -> ${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm ppc x86"
  15 IUSE="alevt usb"
  16
  17 RDEPEND="
  18         alevt? (
  19                 !media-video/alevt
  20                 media-libs/libpng:0=
  21                 media-libs/zvbi[v4l]
  22                 sys-libs/zlib
  23                 x11-libs/libX11
  24         )
  25         usb? ( virtual/libusb:0 )
  26 "
  27 DEPEND="${RDEPEND}
  28         dev-lang/perl
  29         virtual/linuxtv-dvb-headers
  30 "
  31 RDEPEND+="
  32         media-tv/dtv-scan-tables
  33 "
  34
  35 PATCHES=(
  36         "${FILESDIR}"/${PN}-1.1.1.20100223-ldflags.patch
  37         "${FILESDIR}"/${PN}-1.1.1.20100223-alevt.patch
  38         "${FILESDIR}"/${PN}-1.1.1.20100223-perl526.patch
  39         "${FILESDIR}"/${PN}-no-ca_set_pid.patch
  40 )
  41
  42 src_prepare() {
  43         default
  44
  45         # do not compile test-progs, incompatible with videodev2.h
  46         sed -i '/-C test/d' Makefile || die
  47
  48         # remove copy of header-files
  49         rm -rv "${S}"/include/ || die
  50 }
  51
  52 src_compile() {
  53         emake V=1 CC=$(tc-getCC) $(usex usb "ttusb_dec_reset=1" "")
  54         use alevt && emake -C util/alevt CC=$(tc-getCC) OPT="${CFLAGS}"
  55 }
  56
  57 src_install() {
  58         emake V=1 prefix="${EPREFIX}/usr" libdir="${EPREFIX}/usr/$(get_libdir)" \
  59                 $(usex usb "ttusb_dec_reset=1" "") \
  60                 DESTDIR="${D}" INSTDIR="${T}" install
  61
  62         if use alevt ; then
  63                 dodir /usr/share/{applications,man/man1}
  64                 emake -C util/alevt DESTDIR="${D}" install
  65         fi
  66
  67         # rename scan to scan-dvb
  68         mv "${ED}"/usr/bin/scan{,-dvb} || die
  69
  70         # install zap-files
  71         local dir=""
  72         for dir in dvb-{s,c,t} atsc ; do
  73                 insinto /usr/share/dvb/zap/${dir}
  74                 doins "${S}"/util/szap/channels-conf/${dir}/*
  75         done
  76
  77         # install remote-key files
  78         insinto /usr/share/dvb/av7110_loadkeys
  79         doins util/av7110_loadkeys/*.rc*
  80
  81         # install Documentation
  82         dodoc README
  83         newdoc util/scan/README README.scan-dvb
  84         newdoc util/szap/README README.zap
  85         newdoc util/av7110_loadkeys/README README.av7110_loadkeys
  86
  87         use usb && newdoc util/ttusb_dec_reset/README README.ttusb_dec_reset
  88 }
  89
  90 pkg_postinst() {
  91         elog "/usr/bin/scan has been installed as scan-dvb."
  92 }